如何在 Outlook 中根据文件夹名称查找文件夹的完整路径？

请按照以下步骤，在 Outlook 中通过 VBA 根据文件夹名称搜索目标文件夹。

1. 同时按下 "Alt“ + “F11" 键，即可打开 “Microsoft Visual Basic for Applications“ 窗口。

2. 单击“插入” > “模块”，然后将以下 VBA 代码粘贴到新建的模块窗口中。

VBA：在 Outlook 中以文件夹名称搜索并打开文件夹

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. 按下“F5”键或点击“运行”按钮，即可执行该 VBA 程序。

4. 在弹出的“搜索文件夹”对话框中，输入要查找的指定文件夹名称，然后点击“确定”按钮。

注意：该 VBA 支持星号通配符。例如，您可以输入 tes*，即可查找所有以 tes 开头的文件夹。

5. 此时将弹出一个对话框，显示已找到文件夹的路径。若需打开该文件夹，请点击“是”按钮。

现在，已找到的文件夹将在导航窗格上打开，如下截图所示：

注意：如果存在多个同名文件夹，该 VBA 只能查找并打开其中的一个文件夹。

如果您已安装 “Kutools for Outlook“，可利用其 "转到“ 功能，快速根据特定文件夹名称查找所有相关文件夹，并轻松打开任意找到的文件夹。

1. 点击“KUTOOLS PLUS”>“转到”以启用此功能。

2. 在“转到”对话框中，在搜索框内输入指定文件夹名称，从搜索结果中选择目标文件夹后，点击“确定”按钮。

现在，已立即查找并打开带有指定文件夹名称的文件夹。