如何在 Outlook 中按月份对邮件进行分类？

如果您的收件箱中有大量邮件，为了让邮箱界面更加整洁有序，您可以按照邮件接收的具体月份，将邮件存储或归档到不同的文件夹中，如下图所示。通常，您需要手动创建这些文件夹，并逐封移动邮件。显然，这种方式既耗时又繁琐。本文将为您介绍一段能够快速轻松完成此操作的 VBA 代码。

---

使用 VBA 代码按月份分类邮件

要根据月份将邮件移动到不同的文件夹，请应用以下 VBA 代码：

1. 单击选择您要分类邮件的收件箱文件夹。

2. 按住 ALT + F11 键，即可打开 Microsoft Visual Basic for Applications 窗口。

3. 点击插入 > 模块，然后将以下代码粘贴到模块窗口中。

VBA 代码：按月份分类邮件

Sub ClassifyEmailsbyMonth()
'Updateby ExtendOffice
Dim xCurFolder As Folder
Dim xMoveFolder As Folder
Dim xMail As MailItem
Dim I As Long
Dim xYear As String, xMonth As String
On Error Resume Next
Set xCurFolder = Application.ActiveExplorer.CurrentFolder
For I = xCurFolder.Items.Count To 1 Step -1
  DoEvents
  If xCurFolder.Items.Item(I).Class = olMail Then
    Set xMail = xCurFolder.Items.Item(I)
    xYear = Year(xMail.ReceivedTime)
    xMonth = Month(xMail.ReceivedTime)
    Set xMoveFolder = Nothing
    Set xMoveFolder = xCurFolder.Folders(xYear & "." & xMonth)
    If xMoveFolder Is Nothing Then
      Set xMoveFolder = xCurFolder.Folders.Add(xYear & "." & xMonth)
    End If
    xMail.Move xMoveFolder
  End If
Next
Set xMoveFolder = Nothing
Set xCurFolder = Nothing
End Sub

4. 然后，按下 F5 键运行代码，即可将选中收件箱文件夹中的所有邮件按接收时间的具体月份进行分类，如下截图所示：