如何在 Outlook 中为回复和转发邮件分别设置不同的签名？

通常，您可以为 Outlook 中的不同账户设置各自的签名，但您是否想过为回复和转发邮件分别使用不同的签名？也就是说，回复邮件时自动插入签名 1，转发邮件时则应用签名 2. 那么，如何在 Outlook 中实现这一需求呢？

使用 VBA 代码为回复和转发设置不同的签名

---

使用 VBA 代码为回复和转发设置不同的签名

以下 VBA 代码可以帮助您为回复和转发设置不同的签名，请按如下步骤逐步操作：

1. 按住 ALT + F11 键即可打开 Microsoft Visual Basic for Applications 窗口。

2 然后，点击插入> 模块，将以下代码复制并粘贴到打开的空白模块中，如下图所示：

VBA 代码：为回复和转发设置不同的签名：

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

注意：在上述代码中，Signature 1 和 Signature 2 分别为您在回复和转发时使用的两个签名名称。请根据实际需求修改为您自己的签名名称。

3 仍然在 Microsoft Visual Basic for Applications 窗口中，点击工具> 引用，进入 References-Project 1 对话框，并勾选 Microsoft Scripting Runtime 选项，在可用引用列表框中，如下图所示：

4 在点击确定关闭对话框后，以后每次回复邮件时都会立即插入 Signature 1，如下图所示：

而当您转发邮件时，将会插入 Signature 2，如下图所示：