如何在 Outlook 中快速将多个约会批量转换为任务？

本文将为您介绍如何在 Outlook 中快速便捷地将一个或多个约会转换为任务。

通过拖放操作将单个约会转换为任务

通过 VBA 代码将多个约会转换为任务

---

通过拖放操作将单个约会转换为任务

要将单个约会转换为任务，您只需将该约会拖动到任务文件夹，请按照以下步骤操作：

1. 在“日历”窗口中，选中您想要转换为任务的约会事项，然后将其拖动到导航窗格底部的“任务”图标，如下图所示：

2. 随后会弹出新的“任务”窗口，请点击“保存并关闭”按钮，将该约会保存为任务。

---

通过 VBA 代码将多个约会转换为任务

如果您有多个约会需要转换为任务，可以借助下面的 VBA 代码实现，请按如下步骤操作：

1. 按下“Alt + F11”组合键，即可打开“Microsoft Visual Basic for Applications”窗口。

2. 点击“插入”>“模块”，然后将以下代码复制并粘贴到新打开的空白模块中：

VBA 代码：将多个约会转换为任务

Sub ConvertAppointmentsToTasks()
Dim xItemCollection As VBA.Collection
Dim xActiveWindow As Object
Dim xItem As Object
Dim xSelection As Outlook.Selection
Dim xTaskFolder As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xTaskItem As Outlook.TaskItem
On Error Resume Next
Set xItemCollection = New VBA.Collection
Set xActiveWindow = Outlook.Application.ActiveWindow
If TypeOf xActiveWindow Is Inspector Then
    Set xItem = xActiveWindow.CurrentItem
    If xItem.Class = olAppointment Then xItemCollection.Add xItem
Else
    Set xSelection = xActiveWindow.Selection
    If xSelection Is Nothing Then Exit Sub
    For Each xItem In xSelection
        If xItem.Class = olAppointment Then xItemCollection.Add xItem
    Next
End If
Set xTaskFolder = Application.Session.PickFolder
If xTaskFolder Is Nothing Then Exit Sub
For Each xAppointmentItem In xItemCollection
    Set xTaskItem = xTaskFolder.Items.Add(olTaskItem)
    With xTaskItem
        .StartDate = Format(xAppointmentItem.Start, "Short Date")
        .DueDate = Format(xAppointmentItem.End, "Short Date")
        .Subject = xAppointmentItem.Subject & " (From Appt)"
        .Categories = xAppointmentItem.Categories
        .Body = xAppointmentItem.Body
        .Save
        .Display
    End With
Next
End Sub

3. 选中您希望转换为任务的约会后，点击“运行宏”按钮执行此代码。

4. 随后将弹出“选择文件夹”对话框，请选择一个“任务”文件夹，用于保存转换结果。

5. 点击“确定”按钮后，所有选中的约会将被创建为任务。随后，依次保存并关闭“任务”窗口。

6. 现在，您可以进入“任务”文件夹，所有选中的约会都已成功保存为新建任务。