如何在 Outlook 的邮件或任务中查找并替换主题文本？

在 Outlook 中，如果需要将多封邮件或多个任务的主题批量替换为您指定的文本，除了逐一手动修改外，您是否在寻找一种更高效的方法，一次性完成这一操作呢？

通过 VBA 代码在多封邮件中查找和替换主题文本

通过 VBA 代码在多个任务中查找和替换主题文本

---

通过 VBA 代码在多封邮件中查找和替换主题文本

如果需要在多封邮件主题中查找特定文本并替换为其他内容，可以使用以下 VBA 代码帮您实现，请按以下步骤操作：

1. 选中需要查找并替换主题文本的邮件后，按下“ALT + F11”键，打开“Microsoft Visual Basic for Applications”窗口。

2. 然后，点击“插入”>“模块”，将下方代码复制并粘贴到新打开的空白模块中，如下图所示：

VBA 代码：查找和替换多封邮件的主题文本：

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

备注：在上述代码中：xNewSubject = Replace（。Subject， “kte”， “Kutools for Excel”），其中“kte”为您需要查找的旧文本，“Kutools for Excel”为您希望替换的新文本。请根据实际需求进行修改。

3. 接着按下“F5”键运行代码，邮件主题中的指定文本即可被所需的新文本替换，如下图所示：

---

通过 VBA 代码在多个任务中查找和替换主题文本

如果您需要在任务中查找并替换主题文本，以下 VBA 代码同样能够为您提供帮助。

1. 按下“ALT + F11”键，即可打开“Microsoft Visual Basic for Applications”窗口。

2. 然后，点击“插入”>“模块”，将以下代码复制并粘贴到打开的空白模块中，如下图所示：

VBA 代码：查找和替换所有任务的主题文本：

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. 接着按下“F5”键运行代码，此时会弹出一个提示框，请输入您希望在任务主题中查找的文本，如下图所示：

4. 点击“确定”后，将再次弹出提示框，请输入您要替换的新文本，如下图所示：

5. 接着点击“确定”，系统将弹出对话框，告知您已更改的主题数量，如下图所示：

6. 点击“确定”后，任务主题中的原有文本将被新内容替换，效果如下图所示：