如何从 Excel 中的公式提取单元格引用？

假设你有一些较长的公式，现在你想从这些公式中提取所有单元格引用，如下图所示。如何才能尽可能快地从公式中提取单元格引用呢？

使用用户定义函数从公式中提取单元格引用

使用用户定义函数从公式中提取单元格引用

要从公式中提取单元格引用，以下 VBA 代码可能会对你有所帮助。请按照以下步骤操作：

1. 按住 ALT + F11 键打开 Microsoft Visual Basic for Applications 窗口。

2. 单击 插入 > 模块，并将以下代码粘贴到模块窗口中。

VBA 代码：从公式中提取单元格引用：

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. 粘贴代码后，保存代码并返回工作表，在某个单元格中输入此公式：=extractcellrefs(G2)（G2 是包含要提取单元格引用公式的单元格），然后按 Enter 键，所有单元格引用都会从公式中提取出来，参见截图：