跳至主要内容

轻松统计唯一值和不同值 – 7个示例

Author: Xiaoyang Last Modified: 2025-07-31

通常，在 Excel 中，唯一值是指在列表中只出现一次且没有任何重复的值，而不同值是指所有不同的值（唯一值 + 首次出现的重复值）。在处理大型数据集时，您可能需要从如下截图所示的单元格列表中统计唯一值和不同值的数量。本教程将介绍一些在 Excel 中快速统计唯一值和不同值的技巧。

Count unique values or distinct values in a list

在 Excel 中统计唯一值

在 Excel 中统计不同值（唯一值和首次出现的重复值）

下载示例文件

统计唯一值和不同值

在 Excel 中统计唯一值

本节将讨论一些用于统计唯一值数量的公式示例，包括列表中的文本和数字。

使用公式统计唯一值

假设我有一个包含一些重复名称的姓名列表。现在，我需要获取唯一的姓名数量（这些姓名以黄色填充），如下截图所示：

sample data

要解决此问题，以下数组公式可以帮到您：

步骤 1：输入公式

在您希望输出结果的空白单元格中输入或复制以下公式：

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 注意：在上述公式中，“A2:A12” 是您要统计唯一值的数据列表。

步骤 2：按 Ctrl + Shift + Enter 键以获得正确的结果：

Count unique values with formula

注意事项：

  1. 如果您的单元格列表包含其他类型的数据，例如数字、布尔值、错误值等，当应用上述公式时，它将忽略数据类型并统计唯一值的数量。
  2. 当数据列表包含空白单元格时，此公式将排除空白单元格。
  3. 如果存在其他类型的数据并且只想统计唯一的文本值，请应用以下数组公式，然后按“Ctrl”+“Shift”+“Enter”键返回结果： 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. 如果要从包含任何类型数据的单元格列表中仅统计唯一数字，请使用以下数组公式，然后按“Ctrl”+“Shift”+“Enter”键返回结果： 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

通过 Kutools for Excel 仅需几次点击即可统计唯一值

当您下次需要应用公式时，记住它们可能会很痛苦。但是，如果您有“Kutools for Excel”，通过其“公式助手”中的“统计唯一值”选项，只需几次点击即可获得结果。请参见以下演示：

  1. 单击一个单元格以输出结果；
  2. 通过单击“Kutools”>“公式助手”>“公式助手”>“统计”>“统计唯一值”启用此功能；
  3. 选择数据列表 > “确定”。
    Count unique values with kutools
提示：
  1. 要应用此功能，您需要下载并安装 Kutools for Excel。
  2. “公式助手”功能收集了40多个常用公式，例如“提取唯一值”、“提取具有唯一值的单元格（包括首次重复项）”、“统计被逗号分隔的值的数量”、“基于相同文本求和”等……

在 Excel 365/2021 中使用公式统计唯一值

如果您使用的是 Excel 365 或 Excel 2021，有一个新的 UNIQUE 函数可以帮助您创建更简单的公式来统计一组数据中的唯一值。

例如，要统计 A2:A12 范围内的唯一名称数量，请输入以下公式：

步骤 1：复制或输入以下公式

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
注意：在此公式中，“A2:A12” 是您要统计唯一值的数据列表。

步骤 2：按 Enter 键以获得结果：

Count unique values in Excel 365/2021 with formula

提示：

  1. 如果数据列表包含其他类型的数据，例如文本、数字、布尔值、错误值等，此公式将忽略数据类型并统计唯一值的数量。
  2. 上述公式将统计包括空白单元格在内的唯一值，如果您想排除空白单元格，请应用以下公式，并只需按“Enter”键： 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

在 Excel 中统计不同值（唯一值和首次出现的重复值）

要统计单元格列表中的不同值（唯一值和首次出现的重复值），这里我将介绍其他公式来完成此任务。

使用公式统计不同值

在 Excel 中，您可以应用以下任一公式来返回不同值的数量。

步骤 1：输入以下任一公式

公式 1：输入公式后，按“Enter”键。

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

公式 2：输入公式后，按“Ctrl”+“Shift”+“Enter”键。

=SUM(1/COUNTIF(A2:A12,A2:A12))
注意：在这些公式中，“A2:A12” 是您要统计不同值的数据列表。

结果：

Count distinct values with formula

提示：

  1. 如果数据列表包含其他类型的数据，例如数字、布尔值、错误值等，此公式将忽略数据类型并统计不同值的数量。
  2. 当使用上述公式时，如果数据列表包含空白单元格，您将得到 #DIV/0 错误值。要修复并忽略空白单元格，您应该应用以下任一公式：
    公式 1：输入公式后，按“Enter”键。 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    公式 2：输入公式后，按“Ctrl”+“Shift”+“Enter”键。 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Count distinct values exclude blank cells with formula

  3. 要仅获取数据列表中的不同文本值的数量，请应用以下数组公式，并按“Ctrl”+“Shift”+“Enter”键以获得结果： 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. 要仅统计不同的数值，请使用以下数组公式，并按“Ctrl”+“Shift”+“Enter”键以获得结果： 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

通过 Kutools for Excel 仅需几次点击即可统计不同值

如果您需要频繁在工作簿中应用公式，记住它们可能会很痛苦。但是，如果您有“Kutools for Excel”，通过其“公式助手”中的“统计具有唯一值的单元格（包括首次重复项）”选项，只需几次点击即可获得结果。请参见以下演示：

  1. 单击一个单元格以输出结果；
  2. 通过单击“Kutools”>“公式助手”>“统计”>“统计具有唯一值的单元格（包括首次重复项）”启用此功能；
  3. 选择数据列表 > “确定”。
    Count distinct values with kutools
提示：:
  1. 要应用此功能，您需要下载并安装 Kutools for Excel。
  2. “公式助手”功能收集了40多个常用公式，例如“提取唯一值”、“提取具有唯一值的单元格（包括首次重复项）”、“统计被逗号分隔的值的数量”、“基于相同文本求和”等……

使用数据透视表统计不同值

在 Excel 中，数据透视表还可以帮助从数据列表中获取不同值的数量，请按照以下步骤操作：

步骤 1：创建数据透视表

  1. 选择数据列表，然后从功能区单击“插入”>“数据透视表”，请参见截图：
    create a pivottable for selected data
  2. 在弹出的“数据透视表”对话框中：
    (1). 选择放置数据透视表的新工作表或现有工作表；
    (2). 然后勾选“将此数据添加到数据模型”复选框。
    (3). 然后单击“确定”按钮。
    set options in PivotTable from table or range dialog box

步骤 2：排列字段并选择不同计数选项

  1.  显示“数据透视表字段”窗格，将“名称”字段拖动到“值”区域，请参见以下演示：
    Arrange the field for pivottable
  2. 然后，单击“名称计数”下拉菜单，并选择“值字段设置”，请参见截图：
    click value Field Settings option
  3. 然后，将打开一个“值字段设置”对话框，从“汇总值依据”选项卡下的列表框中选择“不同计数”，然后单击“确定”按钮，请参见截图：
    select Distinct Count option

结果：

现在，创建的数据透视表将显示数据列表的不同计数，如下截图所示：

PivotTable result to count distinct values

提示：

  1. 如果您更新了源数据，要获取最新的计数，只需右键单击数据透视表并选择“刷新”选项。
  2. 此“不同计数”选项仅在 Excel 2013 及更高版本中可用。

在 Excel 365/2021 中使用公式统计不同值

在 Excel 365 或 Excel 2021 中，您可以使用新的 UNIQUE 函数与普通的 COUNTA 函数创建一个简单的公式。

请将以下公式复制或输入到空白单元格中，并按“Enter”键以获得结果：

=COUNTA(UNIQUE(A2:A12))
注意：在此公式中，“A2:A12” 是您要统计不同值的数据列表。

Count distinct values in Excel 365/2021 with formula

提示：

  1. 如果数据列表包含其他类型的数据，例如文本、数字、布尔值、错误值等，此公式将忽略数据类型并统计不同值的数量。
  2. 上述公式将统计包括空白单元格在内的不同值，如果您想排除空白单元格，请应用以下公式，并按“Enter”键以获得结果： 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Count distinct values in Excel 365/2021 with formula exclude blank cells

相关文章：

  • 在数据透视表中统计唯一值
  • 默认情况下，当我们根据包含一些重复值的数据范围创建数据透视表时，所有记录都将被统计，但有时我们只想基于某一列统计唯一值以获得正确的截图结果。本文将讨论如何在数据透视表中统计唯一值。
  • 在筛选列中统计唯一值
  • 如果您有一个包含一些重复名称的筛选列列表，现在您只想从这个筛选列表中统计唯一名称的数量。您是否有任何好的解决方案可以在 Excel 中快速处理此任务？
  • 使用多个条件统计唯一值
  • 这里有一组数据，包含几个名称、项目和位置，我们需要做的是找出符合我列出的标准的名称，然后仅统计每个匹配名称一次，如下截图所示。您是否有任何技巧来解决此任务？本文将介绍这些技巧。
  • 连接唯一值
  • 如果我有一个包含一些重复数据的长列表，现在我想找到唯一的值并将它们连接到一个单元格中。如何在 Excel 中快速轻松地处理这个问题？