KutoolsforOffice — 一套方案，五大工具。事半功倍。

如何在 Excel 中对包含或等于 x 或 y 的单元格求和

作者Siluvia修改日期

当单元格包含或等于某一个值或另一个值时求和，本教程将详细提供两种公式，帮助您解决该类问题。

如何在 Excel 中对包含 x 或 y 的单元格求和？
如何在 Excel 中对等于 x 或 y 的单元格求和？

如何在 Excel 中对包含 x 或 y 的单元格进行求和？

如下图所示，若需对 D 列中单元格进行求和，且条件为 C 列中的单元格包含“apple”或“lychee”，您可以使用结合了 SUMPRODUCT、ISNUMBER 和 SEARCH 函数的公式。

doc-如果单元格包含x或y则求和-1

通用公式

=SUMPRODUCT(--((ISNUMBER(SEARCH("criteria 1",rng 1)) + ISNUMBER(SEARCH("criteria 2",rng 2)))>0),sum_rng)

参数说明

Criteria_range 1：要被条件 1 评估的单元格区域；
Criteria_rang 2：要被条件 2 评估的单元格区域；
Criteria 1：用于定义对 Criteria_rang 1 哪些单元格进行求和的条件；
Criteria 2：用于定义对 Criteria_rang 2 哪些单元格进行求和的条件。
Sum_range：需要求和的单元格区域；

如何使用此公式？

选择一个空白单元格，复制或输入以下公式，并按下 Enter 键即可得到结果。

=SUMPRODUCT(--((ISNUMBER(SEARCH(G4,C5:C12))+ISNUMBER(SEARCH(G5,C5:C12)))>0),D5:D12)

doc-如果单元格包含x或y则求和-2

注意事项：在此公式中，G4 和 G5 分别为包含两个条件的单元格。您也可以直接在公式中输入用双引号括起来的实际文本值。

=SUMPRODUCT(--((ISNUMBER(SEARCH("apple",C5:C12))+ISNUMBER(SEARCH("lychee",C5:C12)))>0),D5:D12)

公式解析

=SUMPRODUCT(--((ISNUMBER(SEARCH("apple",C5:C12))+ISNUMBER(SEARCH("lychee",C5:C12)))>0),D5:D12)

ISNUMBER(SEARCH("apple",C5:C12))
>SEARCH("apple",C5:C12)：SEARCH 函数查找“apple”在 C5:C12 区域每个单元格中首次出现的位置，并返回形如 {#VALUE！；#VALUE！；1;9;1；#VALUE！；#VALUE！；18} 的数组。#VALUE！ 表示在对应单元格中未找到“apple”；
>ISNUMBER({#VALUE!;#VALUE!;1;9;1;#VALUE!;#VALUE!;18})：此处 ISNUMBER 函数用于检查数组中引用值是否为数字。若参数为数字，则返回 TRUE，否则返回 FALSE。由此得到新数组 {FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;TRUE}。
ISNUMBER(SEARCH("lychee",C5:C12))：此部分原理与上文相同。此处 ISNUMBER 函数最终返回如下数组 {FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE}；
{FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;TRUE} + {FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE}：随后将这两个数组相加，且计算过程中 TRUE 和 FALSE 会分别转换为 1 和 0. 最终获得数字数组 {0;0;1;2;1;0;1;2}；
({0;0;1;2;1;0;1;2}) > 0：数组中每个数字与 0 进行比较，返回 TRUE 或 FALSE 数组，如 {FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;TRUE}；
--({FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;TRUE})：双减号将 TRUE 转换为 1，将 FALSE 转换为 0. 最终得到新数组 {0;0;1;1;1;0;1;1}；
SUMPRODUCT({0;0;1;1;1;0;1;1},D5:D12)=SUMPRODUCT({0;0;1;1;1;0;1;1},{2000;1600;980;1200;600;900;150;300})：SUMPRODUCT 函数将两个数组中对应元素相乘，并返回形如 {0;0;980;1200;600;0;150;300} 的数组，最后对所有结果求和并最终返回 3230.

如何在 Excel 中对等于 x 或 y 的单元格进行求和？

上文介绍了对包含某一值或另一值的单元格进行求和的公式。本节将演示如何通过相加两个 SUMIF 函数，实现对等于 x 或 y 的单元格求和。

下例用于计算产品为“apple”或“lychee”时的销售总额。

doc-如果单元格包含x或y则求和-3

通用公式

=SUMIF(criteria_range 1,"criteria 1",sum_range)+SUMIF(criteria_range 2,"criteria 2",sum_range)

参数说明

Criteria_range 1：要被条件 1 评估的单元格区域；
Criteria_rang 2：要被条件 2 评估的单元格区域；
Criteria 1：用于定义对 Criteria_rang 1 哪些单元格进行求和的条件。
Criteria 2：用于定义对 Criteria_rang 2 哪些单元格进行求和的条件。
Sum_range：需要求和的单元格区域；

如何使用此公式？

在空白单元格中复制或输入以下公式，并按下 Enter 键即可获取结果。

=SUMIF(C5:C12,G4,D5:D12)+SUMIF(C5:C12,G5,D5:D12)

doc-如果单元格包含x或y则求和-4

注意：该公式引用了包含两个条件的 G4 和 G5 单元格。您也可以直接在公式中输入用双引号括起来的文本值作为条件。

=SUMIF(C5:C12,"apple",D5:D12)+SUMIF(C5:C12,"lychee",D5:D12)

公式说明

=SUMIF(C5:C12,"apple",D5:D12)+SUMIF(C5:C12,"lychee",D5:D12)

第一个 SUMIF 用于统计“apple”的销售额，第二个则用于统计“lychee”的销售额。最后将两者结果相加，即可得到总销售额度。

相关函数

Excel SUMPRODUCT 函数
Excel SUMPRODUCT 函数可用于对两列或多列、数组的对应元素相乘后，将所有乘积进行求和。

Excel ISNUMBER 函数
Excel ISNUMBER 函数可在单元格内容为数字时返回 TRUE，否则返回 FALSE。

Excel SEARCH 函数
Excel SEARCH 函数可以帮助您查找指定字符或子字符串在给定文本字符串中的位置

Excel SUMIFS 函数
Excel SUMIFS 函数可帮助您根据多个条件对单元格数值进行求和。

相关公式

如果单元格包含星号时求和
想要对包含星号且将星号视为普通字符（而非通配符）的单元格进行求和，本教程将为您详细讲解如何结合 SUMIF 函数与波浪号（~） 编写公式。不容错过，立即掌握实用技巧！

如果单元格同时包含 x 和 y 时求和
本分步教程将演示如何使用 SUMIFS 函数，对同时包含 x 和 y 的单元格范围进行求和。

如果日期介于两个日期之间时求和
本教程将演示如何利用基于 SUMIFS 函数的公式，在 Excel 中对特定日期范围内的数值进行求和。

如果单元格等于或不等于某个值时求和
本分步教程将为您详细讲解两种基于 SUMIF 函数的公式，帮助您对等于或不等于指定值的单元格范围进行求和。

最强最佳办公效率工具

Kutools for Excel —— 助您脱颖而出

🤖KUTOOLS AI 助手：基于数据分析的革命性升级智能执行   |  生成代码|  创建自定义公式  |  数据分析及生成图表|  调用 Kutools Functions……
热门功能：查找、高亮或标记重复项  |  删除空白行  |  合并列或单元格且不丢失数据  |  不使用公式的四舍五入……
超级 VLookup：多条件查找  |  多值返回  |  跨多表查找  |  模糊查找……
高级下拉列表：便捷下拉列表  |  联动下拉列表  |  多选下拉列表……
列管理器：添加指定数量的列  |  移动列  |  切换隐藏列可见状态  |对比列与选择相同/不同单元格……
精选功能：网格聚焦  |  设计视图  |  增强编辑栏  |  工作簿和表管理器|资源库（自动文本）|  日期提取  |  汇总工作表  |  加密/解密单元格  |  按列表批量发送邮件  |  超级筛选  |  特殊筛选（筛选粗体单元格/斜体/删除线等） ......
顶级 15 工具集：12 文本工具（添加文本、删除特定字符……）|  50+ 图表 类型（甘特图……）|  40+ 实用公式（基于生日计算年龄……）|  19 插入工具（插入二维码、按路径插入图片……）|  12 转换工具（小写金额转大写、汇率转换……）|  7 合并和拆分工具（高级合并行、拆分 Excel 单元格……）|…… 以及更多
在您的首选语言使用 Kutools —— 支持英语、西班牙语、德语、法语、中文及 40+ 种语言！

Kutools for Excel 拥有超过 300 项功能，让您一键直达所需……

Office Tab —— 让 Microsoft Office（包括 Excel）支持标签式阅读与编辑

  • 一秒即可切换数十个已打开的文档！
  • 每天为您减少数百次鼠标点击，轻松告别鼠标手困扰。
  • 在同时查看和编辑多个文档时，让您的工作效率提升高达 50%。
  • 为 Office（包括 Excel）带来高效标签页体验，畅享如同 Chrome、Edge 和 Firefox 般的便捷操作。