在 Excel 单元格中按特定字符拆分文本字符串

本教程将为您详细介绍如何在 Excel 中通过公式，按指定字符将文本字符串拆分到不同的列。

如何在 Excel 单元格中根据特定字符拆分文本字符串？

假设您的 B 列中有如下图所示的文本字符串列表，您希望在字符“——”处分割文本，并将其输出到三列。此时，以下公式可以帮助您轻松实现。

通用公式

拆分左侧文本的通用公式

=LEFT(text_string,FIND("Char", text_string)-1)

拆分中间文本的通用公式

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

拆分右侧文本的通用公式

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

上述公式的参数解释

如何使用这些公式？

首先，基于特定字符拆分第一个文本字符串

1. 选择一个空白单元格用于输出结果，此处以 C3 为例。

2. 输入下方公式并按下 Enter 键。然后向下拖动包含 LEFT 公式的单元格，即可应用到其他单元格。

=LEFT(B3,FIND("-",B3)-1)

其次，基于特定字符拆分中间文本字符串

1. 选择一个空白单元格（例如 D3）用于输出结果。

2. 请在下方输入公式并按下 Enter 键。选中结果单元格，向下拖动填充柄，即可将公式应用到其他单元格。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

最后，基于特定字符拆分最后的文本字符串

1. 选择一个空白单元格（如 E3）以输出结果。

2. 请在下方输入公式并按下 Enter 键。选中结果单元格，拖动填充柄即可将公式应用到其他单元格。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

现在，B 列中每个单元格的文本字符串都已成功拆分为三部分。

提示：如果您只需按特定字符将文本字符串拆分为两部分，在使用上述 LEFT 公式拆分第一部分后，即可用下方的 RIGHT 公式提取第二部分，如下图所示。

=RIGHT(B3,LEN(B3)-FIND("-",B3))

这些公式是如何运作的？

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)：FIND 函数返回字符“-”在文本字符串 KTE-Jan-359 中首次出现的位置，结果为 4.
• LEFT(B3,4-1)：LEFT 函数可从文本字符串 KTE-Jan-359 的最左侧提取 3 个字符（4-1=3），结果为 KTE。
  注意：由于第一个“——”位于文本字符串的第 4 位，因此需减去 1，以避免提取该字符。

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1：FIND 函数返回字符“-”在文本字符串 KTE-Jan-359 中的位置，此处结果为 4.
  注意：由于第一个“-”位于文本字符串的第 4 位，需要将 1 与 4 相加，以便从该字符后开始提取文本，最终结果为 4+1=5.
• FIND("-",B3,FIND("-",B3)+1) 此处显示为 FIND("-",KTE-Jan-359,4+1)：Find 函数将从 KTE-Jan-359 的第 5 个字符开始查找“-”的位置，并返回结果 8.
• MID(B3, 5, 8 - 4 - 1)：MID(KTE-Jan-359,5,3) 表示 MID 函数将从文本字符串 KTE-Jan-359 的第 5 个字符开始，提取 3 个字符，最终结果为 Jan。

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)：LEN 函数可计算文本字符串 KTE-Jan-359 的总字符数，返回结果为 11.
• FIND("-",B3,FIND("-",B3)+1)：Find 函数从 KTE-Jan-359 的第 5 个字符起查找“-”的位置，并返回结果 8.
• RIGHT(B3,11 - 8))：RIGHT 函数从 KTE-Jan-359 的右侧提取 3（11-8）个字符，结果为 359.

相关函数

相关公式