将尺寸拆分为独立的长、高、宽

本文将为您介绍如何将单元格中的尺寸信息拆分为三部分，分别提取出长度、高度和宽度的具体数值。

如何将尺寸分为三部分？

要将尺寸拆分为独立的长、宽、高，需要分别使用三种不同的公式。

提取第一维的通用公式

=LEFT(text,FIND("char",text)-1)

提取第二维的通用公式

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

提取第三维的通用公式

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

上述公式的参数说明

如何使用这些公式？

首先，需要获取第一维度。

1. 选择一个空白单元格，用于输出第一维数据。

2. 输入以下公式后，按下 Enter 选中结果单元格后，拖动填充柄，即可轻松将公式应用到其他需要的单元格。

=LEFT(B5,FIND("x",B5)-1)

接下来，请按照以下方法拆分第二维。

1. 选择一个空白单元格，用于输出第二维数据。

2. 输入以下公式并按 Enter 键。选中结果单元格并拖动填充柄，将公式应用到其他所需单元格。

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

最后，获取最后一维

1. 选择一个空白单元格，用于输出最终的维度结果。

2. 输入以下公式，然后按 Enter 选中结果单元格后，拖动填充柄即可将公式快速应用到其他所需单元格。

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

这些公式是如何运作的？

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1：FIND 函数用于获取 B5 中第一个“x”的位置。为了得到不包含第一个“x”的第一维，需要将结果减去 1，即 4-1=3.
2. LEFT(B5,3)：LEFT 函数可从 B5 左侧提取 3 个字符，结果为 100.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1：FIND 函数用于定位 B5 单元格中第一个“x”的位置。由于需要在第一个“x”之后获取第二维，因此需加 1. 最终结果为 4+1=5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2)：SUBSTITUTE 函数将 B5 中第二个“x”替换为“@”，结果为 100x 50@300；
• FIND("@",100x 50@300)：此处 FIND 函数用于查找文本 100x 50@300 中“@”字符的位置，返回结果为 7.

3. (FIND("x",B5)+1)：如步骤 1 所述，此处 FIND 函数定位 B5 中第一个“x”并加 1，结果为 5.
4. MID(B5,5,7-(5))：MID 函数从 B5 的第 5 个字符开始提取 2 个字符（7-5=2），最终结果为 50.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5)：LEN 函数计算 B5 中的根据字符串长度筛选总数，返回结果为 10；
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2)：SUBSTITUTE 函数将 B5 中第二个“x”替换为“@”，结果为 100x 50@300；
• FIND("@",100x 50@300)：此处，FIND 函数用于定位文本 100x 50@300 中的“@”，返回结果为 7.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2))：将单元格 B5 的文本总长度减去前 7 个字符后，结果为 3.
4. RIGHT(B5,3)：然后，RIGHT 函数从 B5 的右侧提取 3 个字符，得到的第三维为 300.

相关函数

相关公式