在 Excel 单元格中提取除第一个或最后一个之外的所有单词

在本教程中，我们将学习如何通过公式，在 Excel 中提取单元格中除第一个或最后一个之外的所有单词。

在 Excel 单元格中提取除第一个之外的所有单词
在 Excel 单元格中提取除最后一个之外的所有单词

在 Excel 单元格中提取除第一个之外的所有单词

如下面截图所示，如果您希望从 B 列每个单元格中提取除第一个单词以外的所有内容，可以结合使用 RIGHT、LEN 和 FIND 函数来实现。请按照以下步骤操作。

通用公式

=RIGHT(text_string,LEN(text_string)-FIND(" ",text_string,1))

参数

如何使用这个公式？

1. 选择一个空白单元格用于输出提取的单词，本例中选择的是单元格 D3.

2. 请在该单元格中输入以下公式，并按下 Enter 键。随后，选中该公式单元格并向下拖动，即可将公式应用到其他单元格。

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

现在，指定单元格中除第一个单词外的所有单词都已被成功提取。

注意：上述公式中的 B3 指的是包含除第一个单词外其他内容的单元格，请根据实际需求进行更改。

这个公式是如何运作的？

=RIGHT(B3,LEN(B3)-FIND(" ",B3,1))

1. LEN(B3)：LEN 函数可计算 Excel handy addin 的总长度，并返回结果为 17；

2. FIND(" ",B3,1)：由于单词之间以空格分隔，FIND 函数可定位 Excel handy addin 中第一个空格的位置，并返回结果 6；

3. RIGHT(B3,17-6)：RIGHT 函数可从文本字符串“Excel handy addin”的右侧提取 11 个字符（17-6=11），结果为“handy addin”。

在 Excel 单元格中提取除最后一个之外的所有单词

在本节中，我们将结合使用 LEFT、FIND、SUBSTITUTE 和 LEN 函数，从 Excel 指定单元格中提取除最后一个单词外的所有内容。

通用公式

=LEFT(text_string,FIND("[",SUBSTITUTE(text_string," ","[",LEN(text_string)-LEN(SUBSTITUTE(text_string," ",""))))-1)

参数

如何使用这个公式？

1. 请选择一个空白单元格（如 D3），用于输出提取的单词。

2. 请在该单元格中输入以下公式，并按下 Enter 键。然后向下拖动公式单元格，即可将公式应用到其他单元格。

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

现在，指定单元格中的所有单词都已被提取出来，唯独最后一个单词除外。

注意：上述公式中的 B3 单元格包含除最后一项外需要提取的内容，请根据实际需求进行更改。

这个公式是如何运作的？

=LEFT(B3,FIND("[",SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))-1)

1. SUBSTITUTE(B3," ","[",LEN(B3)-LEN(SUBSTITUTE(B3," ","")))

• LEN(B3)：LEN 函数计算文本“Excel handy addin”的总长度，并将结果返回为 17；
• LEN(SUBSTITUTE(B3," ",""))：SUBSTITUTE 函数会移除“Excel handy addin”中的所有空格，并返回“Excelhandyaddin”，随后 LEN 函数将计算文本“Excelhandyaddin”的总长度。最终结果为 15.
• SUBSTITUTE(B3," ","[",17-15))：SUBSTITUTE(B3，“ “，“【“，2)） 该 SUBSTITUTE 函数会将“Excel handy addin”中的第二个空格替换为“【”字符，并返回结果“Excel handy[addin”。

2. FIND("[","Excel handy[addin")

• FIND 函数用于查找文本字符串“Excel handy[addin”中字符“[”的位置。在该字符串中，“[”位于第 12 个字符，因此结果为 12.

3. =LEFT(B3,12-1)

• LEFT 函数会从文本字符串“Excel handy addin”的左侧提取 11 个字符（12-1=11），最终结果为“Excel handy”。

相关函数

相关公式