KutoolsforOffice — 一套方案，五大工具。事半功倍。

统计一列中唯一的数字值或日期

作者Xiaoyang修改日期

假设您有一个包含重复数字的列表，现在需要统计列表中唯一值或仅出现一次的值的数量，如下图所示。本文将为您介绍几种实用公式，助您在 Excel 中快速高效地完成此任务。

doc-count-unique-values-1

在 Excel 2019、2016 及更早版本中统计一列中的唯一数字值或日期

如果您使用的是 Excel 2019、2016 或更早版本，可以通过常规的 SUM、FREQUENCY、IF、COUNTIF 以及 ISNUMBER 等函数，轻松统计唯一值或仅出现一次的值的数量。

统计一列中唯一的数字值或日期

要从列表中统计唯一数字值，可使用 SUM 和 FREQUENCY 函数，通用公式如下：

=SUM(--(FREQUENCY(range,range)>0))
  • range：需要统计区域内唯一值数量的数据列。

请在空白单元格中输入或复制以下公式，然后按 Enter 键获取结果：

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

doc-count-unique-values-2

公式说明：

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

  • FREQUENCY(A2:A12,A2:A12)：FREQUENCY 函数会返回 A2:A12 区域中每个数字出现的次数，生成如下数组：{1;2;0;2;0;1;1;3;0;0;1;0}。数组中的数值表示对应数字在该列中出现的次数，0 则表示该数字在数据区域中已出现过。
  • --(FREQUENCY(A2:A12,A2:A12)>0)=--({1;2;0;2;0;1;1;3;0;0;1;0})>0：数组中的每个值都会与零进行比较，大于 0 时显示 TRUE，否则显示 FALSE。随后，双负号会将 TRUE 和 FALSE 转换为 1 和 0，最终结果为：{1;1;0;1;0;1;1;1;0;0;1;0}。
  • SUM(--(FREQUENCY(A2:A12,A2:A12)>0))=SUM({1;1;0;1;0;1;1;1;0;0;1;0})：最后，SUM 函数会对数组中的所有值进行求和，最终得出结果：7.
统计一列中只出现一次的唯一数字值或日期

要从列表中统计只出现一次的唯一数字值，应结合 SUM、IF、ISNUMBER 与 COUNTIF 函数编写公式，通用公式如下：

{=SUM(IF(ISNUMBER(range)*COUNTIF(range,range)=1,1,0))}
Array formula, should press Ctrl + Shift + Enter keys together.
  • range：需要统计区域中唯一值数量的数据列。

现在请在空白单元格输入或复制以下公式，然后同时按 Ctrl + Shift + Enter 键以获得正确结果：

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

doc-count-unique-values-3

公式说明：

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

  • ISNUMBER(A2:A12)：ISNUMBER 函数可用于检查 A2:A12 区域中的值是否为数字。若单元格为数字，则返回 TRUE，否则返回 FALSE。因此，将得到如下数组：{TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}。
  • COUNTIF(A2:A12,A2:A12)：COUNTIF 函数可统计每个值在指定范围内出现的次数，返回结果为：{1;2;2;2;2;1;1;3;3;3;1}。
  • ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)={TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}*{1;2;2;2;2;1;1;3;3;3;1}：将上述两个表达式相乘，即可得到结果：{1;2;2;2;2;1;1;3;3;3;1}。
  • IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0)=IF({1;2;2;2;2;1;1;3;3;3;1}=1,1,0)：此处 IF 函数会检查数组中的每个值是否等于 1，若等于则返回 1，否则返回 0. 结果为：{1;0;0;0;0;1;1;0;0;0;1}。
  • SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))=SUM({1;0;0;0;0;1;1;0;0;0;1})：最后，SUM 函数会将数组中的值相加，返回唯一值的总数：4.

在 Excel 365 中统计一列中的唯一数字值或日期

在 Excel 365 中，全新且易用的 UNIQUE 函数已上线。将该函数与 COUNT 函数结合使用，可帮助您高效完成此任务。

统计一列中唯一的数字值或日期

在 Excel 365 中统计唯一数字值或日期的通用公式如下：

=COUNT(UNIQUE(range))
  • range：需要统计区域中唯一值数量的数据列。

请在空白单元格输入或复制下列公式，并按 Enter 键获取结果，见下图：

=COUNT(UNIQUE(A2:A12))

doc-count-unique-values-4

公式说明：

=COUNT(UNIQUE(A2:A12))

  • UNIQUE(A2:A12)：UNIQUE 函数可提取列表中的所有唯一值，结果为以下数组：{258;560;774;801;985;990;1569}。
  • COUNT(UNIQUE(A2:A12))=COUNT({258;560;774;801;985;990;1569})：COUNT 函数统计数值的数量，并返回结果为 7.
统计一列中只出现一次的唯一数字值或日期

此 UNIQUE 函数也可以从列表中提取只出现一次的唯一值，其通用语法为：

=COUNT(UNIQUE(range,0,1))
  • range：需要统计区域内唯一值数量的数据列。

在希望返回结果的单元格中输入或复制以下公式，然后按 Enter 键，如下截图所示：

=COUNT(UNIQUE(A2:A12,0,1))

doc-count-unique-values-5

公式说明：

=COUNT(UNIQUE(A2:A12,0,1))

  • UNIQUE(A2:A12,0,1)：UNIQUE 函数可提取列表中仅出现一次的唯一值，返回如下数组：{258;801;985;1569}。
  • COUNT(UNIQUE(A2:A12,0,1))=COUNT({258;801;985;1569})：COUNT 函数统计数字值的数量，并返回结果为 4.

提示：以上所有公式均可用于统计列中唯一日期的数量。

相关函数用法：

  • SUM：
  • Excel 的 SUM 函数可返回所选数值的总和。
  • FREQUENCY：
  • FREQUENCY 函数用于统计数值在指定区间内出现的频率，并以垂直数组的形式返回结果。
  • ISNUMBER：
  • 当单元格中包含数字时，Excel 的 ISNUMBER 函数将返回 TRUE，否则返回 FALSE。
  • COUNTIF：
  • COUNTIF 函数是 Excel 中一款强大的统计工具，可用于计算满足特定条件的单元格数量。
  • COUNT：
  • COUNT 函数用于统计包含数字的单元格数量，或统计参数列表中的数字个数。
  • UNIQUE：
  • UNIQUE 函数可返回列表或区域中的唯一值列表。

更多相关文章：

  • 按条件统计唯一数字值
  • 在 Excel 工作表中，您可能会遇到需要根据特定条件统计唯一数字值数量的情况。例如，如下图所示，如何统计报表中“T-shirt”产品的唯一数量（Qty）？本文将为您介绍几种公式，助您轻松在 Excel 中实现这一目标。
  • 统计等于多个值之一的单元格数量
  • 假设 A 列为产品列表，现在您希望统计 C4:C6 区域中列出的 Apple、Grape 和 Lemon 这三种特定产品在 A 列中出现的总次数，如下图所示。通常情况下，Excel 的 COUNTIF 和 COUNTIFS 函数难以直接实现这一需求。本文将为您介绍如何结合使用 SUMPRODUCT 和 COUNTIF 函数，快速高效地完成此操作。
  • 统计包含特定字符数的单元格数量
  • 如果您想统计某个范围内正好包含特定字符数（如 5 个字符）的单元格数量，如下图所示，Excel 的 COUNTIF 函数可以为您轻松实现。本文将为您介绍如何获取正好包含 x 个字符的单元格数量，以及如何统计超过指定字符数的单元格数量。

这款最佳办公效率工具

Kutools for Excel —— 助您脱颖而出

🤖KUTOOLS AI 助手：基于数据分析的变革创新智能执行   |  生成代码|  创建自定义公式  |  数据分析及生成图表|  调用 Kutools Functions……
热门功能：查找、高亮显示或标记重复项  |  删除空白行  |  合并列或单元格且不丢失数据  |  不使用公式的四舍五入……
超级 VLookup：多条件查询  |  多值返回  |  跨多工作表  |  模糊查找……
高级下拉列表：轻松下拉列表  |  依赖下拉列表  |  多选下拉列表……
列管理器：添加指定数量的列  |  移动列  |  切换隐藏列的显示状态  |比较列与选择相同/不同单元格……
特色功能：网格聚焦  |  设计视图  |  增强编辑栏  |  工作簿和表管理器|资源库（自动文本）|  日期提取  |  汇总工作表  |  加密/解密单元格  |  按列表群发邮件  |  超级筛选  |  特殊筛选（筛选粗体单元格/斜体/删除线……） ......
顶级 15 工具组：12 文本工具（添加文本，删除特定字符……）|  50+ 图表 类型（甘特图……）|  40+ 实用公式（基于生日计算年龄……）|  19 插入工具（插入二维码，按路径插入图片……）|  12 转换工具（小写金额转大写，汇率转换……）|  7 合并和拆分工具（高级合并行，拆分 Excel 单元格……）|……以及更多
在您的首选语言中使用 Kutools——支持英语、西班牙语、德语、法语、中文以及 40+ 种其他语言！

Kutools for Excel 拥有超过 300 项功能，让您的需求一键轻松实现……

Office Tab —— 让 Microsoft Office（包括 Excel）支持标签式阅读与编辑

  • 一秒即可切换数十个已打开的文档！
  • 每天为您减少上百次鼠标点击，轻松告别鼠标手困扰。
  • 查看和编辑多个文档时，工作效率提升 50%。
  • 为 Office（包括 Excel）引入高效标签页，让您同样畅享如 Chrome、Edge 和 Firefox 般的便捷体验。