如何将 Word 文档中的每一页分别另存为独立的 PDF 文件？

作者Siluvia修改日期2025-04-11

在 Microsoft Word 中，您可以利用内置的“另存为”功能，并在选项对话框中指定页码，将每一页手动单独保存为 PDF 文件。但当文档页数达到数百页时，手动操作将极为耗时。本文将为您介绍一种能够高效、快速地将所有页面分别保存为独立 PDF 文件的方法。

使用 VBA 代码批量将每一页另存为独立的 Pdf 文件

您只需使用以下 VBA 代码，即可将 Word 文档的每一页自动单独另存为 Pdf 文件。具体操作步骤如下：

打开需要处理的 Word 文档。按下 Alt + F11，即可打开 Microsoft Visual Basic for Applications 窗口。

在 Visual Basic 窗口中，点击“插入” > “模块”，然后将以下 VBA 代码粘贴到模块窗口中：

Sub SaveAsSeparatePDFs()
'Updated by Extendoffice 20180906
    Dim I As Long
    Dim xStr As String
    Dim xPathStr As Variant
    Dim xDictoryStr As String
    Dim xFileDlg As FileDialog
    Dim xStartPage, xEndPage As Long
    Dim xStartPageStr, xEndPageStr As String
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    If xFileDlg.Show <> -1 Then
        MsgBox "Please chose a valid directory", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xPathStr = xFileDlg.SelectedItems(1)
    xStartPageStr = InputBox("Begin saving PDFs starting with page __? " & vbNewLine & "(ex: 1)", "Kutools for Word")
    xEndPageStr = InputBox("Save PDFs until page __?" & vbNewLine & "(ex: 7)", "Kutools for Word")
    If Not (IsNumeric(xStartPageStr) And IsNumeric(xEndPageStr)) Then
        MsgBox "The enterng start page and end page should be number format", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    xStartPage = CInt(xStartPageStr)
    xEndPage = CInt(xEndPageStr)
    If xStartPage > xEndPage Then
        MsgBox "The start page number can't be larger than end page", vbInformation, "Kutools for Word"
        Exit Sub
    End If
    If xEndPage > ActiveDocument.BuiltInDocumentProperties(wdPropertyPages) Then
        xEndPage = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
    End If
    For I = xStartPage To xEndPage
        ActiveDocument.ExportAsFixedFormat xPathStr & "\Page_" & I & ".pdf", _
        wdExportFormatPDF, False, wdExportOptimizeForPrint, wdExportFromTo, I, I, wdExportDocumentWithMarkup, _
        False, False, wdExportCreateHeadingBookmarks, True, False, False
    Next
End Sub

按下 F5 即可运行代码。
在弹出的浏览窗口中，选择要保存 Pdf 文件的文件夹，然后点击“确定”。
在第一个“Kutools for Word”对话框中，输入起始页码后点击“确定”。
在第二个“Kutools for Word”对话框中，输入结束页码后，点击“确定”。
注意：例如，如果您想保存连续的几页，如第 4、5 和 6 页，只需在两个对话框中分别输入“4”和“6”即可。