如何将生日从 Excel 导入到日历？

如果您在某个工作表中有一长列生日信息，现在想将这些生日作为事件导入到您的日历中，有哪些快捷的方法可以实现这一操作？

---

使用 VBA 代码将生日从 Excel 导入到日历

通常没有直接方法可以将生日导入日历，这里我将通过创建 VBA 代码来解决该问题，请按照以下步骤操作：

1. 打开包含需导入到 Outlook 的生日信息的工作表，然后按下 ALT + F11 组合键，打开 Microsoft Visual Basic for Applications 窗口。

2. 点击插入 > 模块，然后将以下代码粘贴到模块窗口中。

VBA 代码：将生日导入到日历

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. 在 Microsoft Visual Basic for Applications 窗口中，点击工具 > 引用。在弹出的 引用 —— VBAProject对话框中，于可用引用列表框中勾选 Microsoft Outlook 16.0 Object Library 选项，如下图所示：

4. 然后点击确定关闭此对话框。现在，请按 F5 键运行代码，届时会弹出提示框，请选择姓名和生日所在的列，如下图所示：

5. 接着点击确定按钮，生日信息将立即导入日历，您可在 Outlook 中打开查看导入结果，如下图所示：