如何一次性清除 Outlook 中的所有类别？

假如您在 Outlook 中有大量项目已分配了颜色类别，若想要快速且轻松地一次性清除所有项目的类别，该如何操作？

使用“清除所有类别”功能从指定文件夹中移除所有类别

使用 VBA 代码从指定帐号中移除所有类别

---

使用“清除所有类别”功能从指定文件夹中移除所有类别

如果您仅需清除指定文件夹中的类别，请按如下步骤操作：

1. 单击您想要移除颜色类别的文件夹，然后按下 Ctrl + A，即可全选所有项目。

2. 在右键菜单中，右键单击后选择分类> 清除所有类别，如下图所示：

3. 此后，指定文件夹中的所有颜色类别将被一键清除。

---

使用 VBA 代码从指定帐号中移除所有类别

如果您需要从某个账户中的所有项目（如邮件、任务、联系人、便笺等）清除所有类别，可以使用以下 VBA 代码来实现：

1. 选中您想要清除所有类别的账户邮件，然后按住 ALT + F11 键，打开 Microsoft Visual Basic for Applications 窗口。

2. 点击插入 > 模块，然后将以下宏粘贴到模块窗口中。

VBA 代码：从指定账户中清除所有类别：

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. 按下 F5 键运行代码后，将弹出提示框，提醒您选定账户的所有类别已被清除，见下图：