如何在 Outlook 的已发送邮件文件夹中实现正常回复？

通常，当您在已发送邮件文件夹中点击“回复”功能，准备再次发送邮件给原收件人时，您的邮箱地址会自动显示在收件人栏（To 字段），如下图所示。每次都需要手动更改收件人地址，确实会带来不便。如何让 Outlook 自动使用原始收件人地址，而不是显示您自己的邮箱？

通过“全部回复”功能在 Outlook 的已发送邮件文件夹中正常回复

通过 VBA 代码在 Outlook 的已发送邮件文件夹中正常回复

---

通过“全部回复”功能在 Outlook 的已发送邮件文件夹中正常回复

在 Outlook 中，“全部回复”功能可以帮助您解决此问题，请按以下步骤操作：

如果您需要再次回复已发送邮件，并希望保留原始收件人的地址，请点击“全部回复”按钮，那么原始收件人的地址会显示在“收件人”字段中，如下图所示：

---

通过 VBA 代码在 Outlook 的已发送邮件文件夹中正常回复

有时，在回复已发送邮件时，您可能会忘记使用“全部回复”功能。下面的 VBA 代码可帮助您在已发送邮件文件夹中，通过“回复”功能正常进行回复。请按照以下步骤操作：

11. 按住 ALT + F11 键，即可打开 Microsoft Visual Basic for Applications 窗口。

22. 在 Microsoft Visual Basic for Applications 窗口中，双击 Project 1(VbaProject.OTM) 窗格中的 ThisOutlookSession，打开模块后，将以下代码复制粘贴到空白模块中。

VBA 代码：在 Outlook 的已发送邮件文件夹中正常回复：

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

33. 保存代码后，重启 Outlook 以使代码生效。现在，当您在已发送邮件文件夹中点击“回复”重新发送邮件时，原始收件人的地址会自动显示在收件人栏，轻松满足您的需求。