如何在 Outlook 中按类别打印任务？

假如您的 Outlook 任务中包含多种颜色类别，您希望将任务列表按类别分别打印在不同页面，该如何在 Outlook 中实现这一需求？

手动逐个在不同页面上按类别打印任务

使用 VBA 代码将任务按类别分页面打印

---

手动逐个在不同页面上按类别打印任务

在 Outlook 中，您可以按照不同类别，手动逐一在不同页面打印任务列表，请按以下方法操作：

11. 启动 Outlook，进入任务窗格，选择您要打印的任务文件夹，然后按下 Ctrl + E 激活搜索框，接着在搜索选项卡上，点击“已分类”图标，并选择您需要打印的颜色类别，如图所示：

22. 此时，所有带有该特定颜色类别的任务将会全部列出，如下截图所示：

33. 然后，继续点击文件> 打印，即可按照如下截图所示打印出该任务列表：

4. 请按照上述步骤，依次手动打印出其他颜色类别的任务列表。

---

使用 VBA 代码将任务按类别分页面打印

这里提供一个 VBA 代码，可以帮助您一次性根据类别，将任务打印在不同页面，请按照以下步骤操作：

11. 进入任务窗格，选择需要打印的任务文件夹。

22. 按下 ALT + F11 组合键，即可打开 Microsoft Visual Basic for Applications 窗口。

33. 接着，点击插入> 模块，将以下代码复制粘贴到打开的空白模块中：

VBA 代码：按类别分页面打印任务：

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

44. 然后点击工具> 引用，在 Microsoft Visual Basic for Applications 窗口中，在弹出的 “引用-Project 1” 对话框，勾选 Microsoft Excel 对象库和 Microsoft Scripting Runtime 选项，并在“可用引用”列表框中找到，如下图所示：

55. 最后，点击确定按钮。现在，请按下 F5 键运行代码，执行完毕后，不同类别的任务列表将分别打印在各自页面。不容错过，立即体验高效分类！