如何在 Outlook 中根据收件人自动切换签名？

默认情况下，Outlook 内置了一个功能，可让用户在通过不同电子邮件账户发送邮件时自动切换签名。除此之外，本文还将为您介绍如何根据 Outlook 中“收件人”字段的不同，自动更换签名的方法。

使用 VBA 代码根据收件人自动更换签名

---

使用 VBA 代码根据收件人自动更换签名

请按照以下步骤，在 Outlook 发送邮件时为不同的收件人自动应用相应的签名。

1. 首先，您需要在 Outlook 中关闭自动附加签名功能。请点击文件 > 选项，即可打开 Outlook 选项窗口。

2. 在 Outlook 选项窗口左侧选择邮件，然后在撰写邮件部分点击签名按钮。见下图：

3. 在签名和信纸对话框中，切换到选择默认签名栏目下的电子邮件签名选项卡，在电子邮件帐户下拉列表中选择电子邮件帐户，然后将新邮件和回复/转发下拉列表都设置为(无）。重复此操作，直到所有账户都设置为(无）。最后，点击确定按钮。

注意：您也可以在此签名和信纸对话框中创建所需的签名。

4. 在返回 Outlook 选项窗口时，点击确定按钮。

5. 请按下 Alt+F11 键，即可打开 Microsoft Visual Basic for Applications 窗口。

6. 在 Microsoft Visual Basic for Applications 窗口左侧双击 ThisOutlookSession，即可打开代码窗口，并将下方 VBA 代码粘贴到该窗口。见截图：

VBA 代码：根据收件人在 Outlook 中自动更换签名

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

注意事项：

• 1)。在 VBA 代码中，请将 “邮箱地址 1/2/3/4" 替换为对应收件人的邮箱地址。
• 2)。“aaa.htm“、“bbb.htm" 和 “ccc.htm" 是您为不同收件人分别设置的专属签名。
• 3)。在此情况下，签名“aaa"将发送给“邮箱地址 1“，签名“bbb"将发送给“邮箱地址 2"和“邮箱地址 3"，而“邮箱地址 4"则会收到带有签名“ccc"的邮件。请根据您的需求进行调整。
• 4)。如果一封邮件包含多个收件人，代码仅会考虑第一个收件人。在此情况下，其他收件人将收到与第一个收件人相同签名的邮件。

7. 然后点击工具 > 引用，进入引用 —— 项目对话框。在该对话框中，请勾选 Microsoft Word Object Library 和 Microsoft Scripting Runtime 选项，随后点击确定按钮。见截图：

8. 按下 Alt+Q 键，即可关闭 Microsoft Visual Basic for Applications 窗口。

从现在起，每当您编写邮件并点击发送按钮后，系统将会根据“收件人”栏中的邮箱地址，自动在邮件正文末尾插入对应的签名。

---