如何在Outlook中一次发送多个草稿？

现在，如果您的“草稿”文件夹中有多条草稿消息，则希望一次发送一次，而不是一一发送。 您如何在Outlook中快速轻松地处理这项工作？

使用VBA代码一次在Outlook中发送所有草稿邮件

使用VBA代码一次在Outlook中发送所有草稿邮件

以下VBA代码可以帮助您立即从“草稿”文件夹发送所有或选定的草稿电子邮件，请这样做：

1。 按住 ALT + F11 键打开 Microsoft Visual Basic应用程序 窗口。

2。 然后点击 插页 > 模块，将以下代码复制并粘贴到打开的空白模块中，请参见屏幕截图：

VBA代码：在Outlook中一次发送所有草稿电子邮件：

Sub SendAllDraftEmails()
Dim xAccount As Account
Dim xDraftFld As Folder
Dim xItemCount As Integer
Dim xCount As Integer
Dim xDraftsItems As Outlook.Items
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xCurFld As Folder
Dim xTmpFld As Folder
On Error Resume Next
xItemCount = 0
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    xItemCount = xItemCount + xDraftFld.Items.Count
    If xDraftFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
Set xDraftFld = Nothing
If xItemCount > 0 Then
   xPromptStr = "Are you sure to send out all the drafts?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        If Not xTmpFld Is Nothing Then
            Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        End If
        VBA.DoEvents
        For Each xAccount In Outlook.Application.Session.Accounts
            Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
            Set xDraftsItems = xDraftFld.Items
            For i = xDraftsItems.Count To 1 Step -1
                If xDraftsItems.Item(i).Recipients.Count <> 0 Then
                    xDraftsItems.Item(i).sEnd
                    xCount = xCount + 1
                End If
            Next
        Next xAccount
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No Drafts!", vbInformation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

3。 然后保存代码，然后按 F5 键以运行此代码，将弹出一个提示框，提醒您是否发送所有草稿，请单击 有，请参见屏幕截图：

4。 然后会弹出一个对话框，提醒您已发送了多少电子邮件草稿，请参见屏幕截图：

5。 然后点击 OK 按钮中的所有电子邮件 草稿箱 文件夹将立即发送，请参见屏幕截图：

笔记：

1.上面的代码将发送Outlook中所有帐户的所有电子邮件草稿。

2.如果您只想从“草稿”文件夹发送一些特定的电子邮件，请应用以下VBA代码：

VBA代码：从“草稿”文件夹发送选定的电子邮件：

Sub SendSelectedDraftEmails()
Dim xSelection As Selection
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xAccount As Account
Dim xCurFld As Folder
Dim xDraftsFld As Folder
Dim xTmpFld As Folder
Dim xArr() As String
Dim xCount As Integer
Dim xMail As MailItem
On Error Resume Next
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftsFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    If xDraftsFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
If xTmpFld Is Nothing Then
    MsgBox "The current folder is not a draft folder", vbInformation, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection.Count > 0 Then
    xPromptStr = "Are you sure to send out the selected " & xSelection.Count & " draft item(s)?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        ReDim xArr(xSelection.Count - 1)
        For i = 1 To xSelection.Count
            xArr(i - 1) = xSelection.Item(i).EntryID
        Next
        Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        VBA.DoEvents
        For i = 0 To UBound(xArr)
            Set xMail = Application.Session.GetItemFromID(xArr(i))
            If xMail.Recipients.Count <> 0 Then
                xMail.sEnd
                xCount = xCount + 1
            End If
        Next
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No items selected!", vbInformation, "Kutools for Outlook"
End If
End Sub

相关文章：

如何在Outlook中分别向多个收件人发送电子邮件？

如何通过Outlook从Excel向列表发送个性化大量电子邮件？

如何在Outlook中分别向多个收件人发送日历？

如何在Outlook中未知的情况下向多个收件人发送电子邮件？

---

Kutools for Outlook-为Outlook带来100个高级功能，并使工作更加轻松！

• 自动CC / BCC 根据规则发送电子邮件； 自动转发 自定义多封电子邮件； 自动回复 没有交换服务器，还有更多自动功能...
• BCC警告 -当您尝试全部答复时显示消息 如果您的邮件地址在“密件抄送”列表中; 缺少附件时提醒，还有更多提醒功能...
• 在邮件对话中回复（全部）带有所有附件; 回复许多电子邮件 很快; 自动添加问候语 回复时将日期添加到主题中...
• 附件工具：管理所有邮件中的所有附件， 自动分离, 全部压缩，全部重命名，全部保存...快速报告， 计算选定的邮件...
• 强大的垃圾邮件 习俗 删除重复的邮件和联系人... 使您能够在Outlook中做得更聪明，更快和更好。

阅读更多 现在下载...