如何在 Outlook 中将邮件另存为图片格式（JPG/TIFF）？

您是否曾尝试在 Outlook 中将邮件保存为图片（如 jpg 或 tiff 格式）？本文将为您详细介绍实现这一需求的方法。

使用 VBA 代码将邮件保存为图片格式

---

使用 VBA 代码将邮件保存为图片格式

请按照以下步骤，在 Outlook 中将邮件保存为图片格式。

1. 选中您想要保存为图片的邮件，同时按下 Alt+F11 组合键，即可打开 Microsoft Visual Basic for Applications 窗口。

2. 在 Microsoft Visual Basic for Applications 窗口中，请点击插入 > 用户窗体。见截图：

3. 创建如下截图所示的用户窗体，轻松开启高效操作体验。

4. 在左侧属性窗格中，选择 jpg 选项按钮，并将其名称更改为 opbJPG。

5. 重复步骤 4，将其他选项按钮重命名为 opbTIFF。同时，将 OK 命令按钮和 Cancel 命令按钮分别重命名为 cdbOk 和 cdbCancel。

注意：如果在 Microsoft Visual Basic for Applications 窗口中未显示属性窗格，请按 F4 键即可显示属性窗格。

6. 在用户窗体上任意空白处双击，即可打开代码窗口。将所有代码替换为下方 VBA 脚本后，关闭代码窗口。

VBA 代码 1：将邮件保存为图片

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. 选择 UserForm 1，在属性窗格中将其名称更改为 FrmPicType，如下截图所示。

8. 点击插入> 模块，然后将下方 VBA 代码复制到模块窗口即可。

VBA 代码 2：将邮件保存为图片

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. 点击工具 > 引用，勾选 Microsoft PowerPoint Object Library 复选框，然后点击 OK 按钮。见截图：

10. 按下 F5 键运行代码。随后会弹出 UserForm 1 对话框，请选择图片类型后点击 OK 按钮。不容错过，见截图：

11. 在浏览文件夹对话框中，指定图片的保存文件夹，然后点击 OK 按钮即可。

12. 最后，会弹出 Microsoft Outlook 对话框，提示保存已完成。请点击 OK 按钮确认。

所选邮件已成功转换为 JPG 或 TIFF 图片，并保存至指定文件夹。

---

相关文章：

• 如何在 Outlook 中将多封邮件中的所有附件批量保存到指定文件夹？
• 如何在 Outlook 中删除邮件中的所有附件？