如何在Outlook中通过文件夹名称查找文件夹（完整文件夹路径）？

请按照以下步骤在Outlook中通过文件夹名称使用VBA搜索文件夹。

1. 同时按下“Alt” + “F11”键以打开“Microsoft Visual Basic for Applications”窗口。

2. 点击“插入” > “模块”，然后将以下VBA代码粘贴到新的模块窗口中。

VBA：在Outlook中按文件夹名称搜索和打开文件夹

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. 按下“F5”键或点击“运行”按钮以运行此VBA。

4. 在弹出的“搜索文件夹”对话框中，请输入要搜索的指定文件夹名称，然后点击“确定”按钮。

注意：此VBA支持星号通配符。例如，您可以输入tes*以查找所有名称以tes开头的文件夹。

5. 现在一个对话框弹出并显示找到的文件夹路径。如果您需要打开找到的文件夹，请点击“是”按钮。

现在，找到的文件夹已在导航窗格中打开，如下截图所示：

注意：如果有多个文件夹使用指定名称命名，则此VBA只能找到并打开其中一个文件夹。

如果您已安装“Kutools for Outlook”，则可以应用其“打开文件夹”功能快速按某个文件夹名称找到所有文件夹，并轻松打开任何一个找到的文件夹。

1. 点击“Kutools Plus” > “打开文件夹”以启用此功能。

2. 在“打开文件夹”对话框中，请在“搜索”框中输入指定的文件夹名称，选择搜索结果中的一个文件夹，然后点击“确定”按钮。

现在，具有特定文件夹名称的指定文件夹已被找到并立即打开。