如何导出并打印 Outlook 中所有文件夹及其子文件夹的列表？

一般情况下，您可以通过按“Ctrl”+“6”在 Outlook 的导航窗格中查看所有文件夹列表，但无法直接打印该列表。本文将为您介绍两段 VBA 脚本，帮助您导出并打印 Outlook 中所有文件夹及其子文件夹的列表。

• 在新建邮件中导出并打印所有 Outlook 文件夹及其子文件夹的列表
• 在记事本中导出并打印所有 Outlook 文件夹及其子文件夹的列表

---

在新建邮件中导出并打印所有 Outlook 文件夹及其子文件夹的列表

本方法介绍了如何通过 VBA 脚本，将指定电子邮件帐户下所有文件夹及其子文件夹的列表导出到 Outlook 的新建邮件中，方便您轻松打印文件夹列表。

1. 按下“Alt”+“F11”组合键，即可打开 Microsoft Visual Basic for Applications 窗口。

2. 点击“插入”>“模块”，然后将以下 VBA 代码粘贴到新建的模块窗口中。

VBA：导出 Outlook 中新建邮件的文件夹及子文件夹列表

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. 按下“F5”键运行 VBA。

4. 在弹出的“选择文件夹”对话框中，选择您希望打印文件夹列表的电子邮件账户，然后点击“确定”。

5. 所选账号的文件夹列表将会被复制到新建邮件中，如下所示。点击“文件”>“打印”即可打印该文件夹列表。

6. 打印完成后，关闭新建邮件，无需保存。

---

在记事本中导出并打印所有 Outlook 文件夹及其子文件夹的列表

本方法将为您介绍如何通过 VBA 脚本，将指定电子邮件账户下所有文件夹及其子文件夹的列表，从 Outlook 导出到记事本，助您轻松打印所需的文件夹清单。

1. 按下“Alt”+“F11”组合键，即可打开 Microsoft Visual Basic for Applications 窗口。

2. 点击“插入”>“模块”，然后将以下 VBA 代码粘贴到新建的模块窗口中。

VBA：将所有 Outlook 文件夹及其子文件夹从 Outlook 导出到记事本

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. 按下“F5”运行 VBA。在弹出的选择文件夹对话框中，选择您希望导出并打印文件夹列表的电子邮件账户，然后点击“确定”。

4. 此时会弹出“输出文件夹树”对话框，根据是否需要显示树状缩进，点击“是”或“否”。

现在，桌面上会新建一个名为“Outlook-Folders”的纯文本，如下所示：

5. 双击打开新建的纯文本文件，点击“文件”>“打印”即可打印导出的 Outlook 文件夹列表。

相关文章

在 Outlook 中显示或隐藏文件夹列表视图