如何获取 Outlook 的文件夹列表？

有时，在导航窗格中以树形结构显示所有邮件文件夹（包括自建的个人文件夹），能够为 Outlook 用户带来极大便利。若想快速列出完整的文件夹树结构，可以借助 VBA 代码轻松实现。本教程将为您详细介绍如何通过 VBA 代码轻松获取文件夹列表。

使用 VBA 代码获取 Outlook 文件夹列表

---

使用 VBA 代码获取 Outlook 文件夹列表

要通过 VBA 代码获取 Outlook 文件夹列表，请按照以下步骤操作。

1. 按下键盘上的“Alt” + “F11”组合键，即可打开“Microsoft Visual Basic for Applications”窗口。

2. 然后双击“Project 1” > “Microsoft Outlook Object” > “ThisOutlookSession”，即可打开“Project 1 – ThisOutlookSession”窗口。请参见下方截图：

3. 然后，将以下 VBA 代码复制并粘贴到 Project 1 – ThisOutlookSession 窗口中。

VBA：获取 Outlook 文件夹列表

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. 按下键盘上的“F5”键，即可开始运行 VBA 代码。

5. 此时将弹出“宏”对话框，请点击“运行”按钮。

6. 请等待宏运行结束。随后，所有邮件文件夹列表将立即显示在新建邮件窗口中，方便您直接打印。请参见下方截图：

注意：此 VBA 代码适用于 Outlook 2007、2010 和 2013 版本。