根据 Excel 中的数据列表批量创建多个文件夹和子文件夹

假设您的工作表中有一份员工姓名列表，并希望为每位员工单独创建文件夹来存储其相关信息。手动逐个创建不仅繁琐，还极其耗时。不过，其实有更高效的方法可以大幅加速这一流程。在本指南中，我将为您分享几种快速根据指定单元格内容批量生成文件夹的实用方法。

根据单元格值创建文件夹

• 使用 MD 命令和记事本
• 使用强大功能 – Kutools for Excel
• 使用 VBA 代码

使用 VBA 代码根据单元格值创建文件夹和子文件夹

根据单元格值创建文件夹

本节将深入介绍多种方法，并提供清晰详尽的分步指南，助您快速、轻松地根据单元格值列表创建文件夹。

使用 MD 命令和记事本从列表创建文件夹

利用 MD 命令与记事本将 Excel 列表转换为文件夹，是一种巧妙高效的方法——它将简洁的批处理脚本与 Excel 强大的数据组织能力完美结合，轻松实现批量文件夹创建，省去繁琐的手动操作。以下是完成此任务的分步指南：

步骤 1：使用 MD 命令创建公式

将以下公式复制或输入到首个单元格值（例如 B1）旁边的空白单元格中，然后向下拖动填充柄，即可将公式应用到所有列表项。

="MD "&A1

步骤 2：将公式复制并粘贴到记事本文件中

1. 按“Ctrl + C”复制包含 MD 命令公式的单元格。
2. 打开记事本，按“Ctrl + V”将命令粘贴到生成文件中。
   

步骤 3：将记事本文件另存为 .bat 文件

在记事本中，单击“文件”选项卡下的“另存为”。在弹出的“另存为”对话框中，选择您希望创建多个文件夹的目标目录，为该文件指定一个名称，并添加 .bat 扩展名，然后单击“保存”按钮。请参见截图：

步骤 4：双击 .bat 文件以生成多个文件夹

1. 关闭记事本文件，导航至您之前保存 .bat 文件的文件夹。
2. 现在，见证奇迹时刻：双击该文件，多个文件夹将同时创建。请参见下方演示：
   

使用强大工具——Kutools for Excel 从列表创建文件夹

借助强大的 Kutools for Excel「基于区域创建文件夹」功能，您可轻松快速地从 Excel 列表生成文件夹。不仅如此，Kutools 还支持一键创建包含多级子文件夹的复杂结构。只需几个简单步骤，即可将 Excel 数据转化为井然有序的文件夹系统，显著提升工作效率。

安装 Kutools for Excel 后，请单击“KUTOOLS PLUS”>“导入导出”>“基于区域创建文件夹”以打开基于区域创建文件夹对话框：

1. 选择您要基于其创建文件夹的单元格值；
2. 然后，单击按钮，指定要保存这些文件夹的目标文件夹；
3. 最后，单击“确定”按钮。
   

结果：

Kutools 将为您处理工作表中的列表，并在指定的目标位置为每个条目创建一个文件夹。请前往目标文件夹查看结果。参见截图：

使用 VBA 代码从列表创建文件夹

在 Excel 中，借助 VBA 代码，您可以将根据列表创建文件夹这一繁琐任务转变为快速、自动化的高效流程。本节将为您演示如何运用 VBA 代码轻松生成文件夹。

步骤 1：打开 VBA 模块编辑器并复制代码

1. 在 Excel 中按住 Alt + F11 键，即可打开“Microsoft Visual Basic for Applications”窗口。
2. 单击“插入”>“模块”，并将以下代码粘贴到模块窗口中。
   VBA 代码：根据单元格值列表创建文件夹

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

步骤 2：执行代码

1. 粘贴此代码后，请按 F5 键运行。在弹出的提示框中，选择您希望用于创建文件夹的单元格值，然后单击“确定”。
   
2. 随后，在弹出的“选择目标文件夹”窗口中，指定用于输出所创建文件夹的目标路径，然后单击“确定”按钮。请参见截图：
   

结果：

执行 VBA 代码后，请前往目标目录查看结果——您将看到为 Excel 列表中每个项目新建的文件夹。请参见截图：

使用 VBA 代码根据单元格值创建文件夹和子文件夹

有时，您可能需要根据 Excel 单元格中的数据，不仅创建文件夹，还能同步生成对应的子文件夹。为此，我将为您介绍一段实用的 VBA 代码。

步骤 1：准备数据

首先，请按如下图所示输入数据：将主文件夹名称置于第一列，子文件夹名称置于第二列。

步骤 2：打开 VBA 模块编辑器并复制代码

1. 在 Excel 中按住 Alt + F11 键，即可打开“Microsoft Visual Basic for Applications”窗口。
2. 单击“插入”>“模块”，并将以下代码粘贴到模块窗口中。
   VBA 代码：根据单元格值创建文件夹和子文件夹

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

步骤 3：执行代码

1. 粘贴此代码后，请按 F5 键运行。在弹出的提示框中，选择您希望用于创建文件夹的单元格值，然后单击“确定”。
   
2. 在随后弹出的窗口中，指定用于输出所创建文件夹的目标路径，然后单击“确定”按钮。请参见截图：
   

结果：

执行 VBA 代码后，请前往目标目录查看结果。您将看到，系统已根据单元格中的值成功创建了相应的文件夹及其子文件夹，如下图所示：

相关文章：