如何使用 Excel 计算 Pdf 文件的页数？

如果文件夹中有多个 PDF 文件，并且需要在 Excel 中列出它们的文件名及其页数，可以使用一个简单的 VBA 宏轻松实现。本教程将引导您完成快速提取并显示 PDF 文件名及其对应页码到 Excel 工作表中的步骤。

使用 VBA 在 Excel 中显示 PDF 文件名和页码

使用 VBA 在 Excel 中显示 PDF 文件名和页码

以下 VBA 代码可以帮助您在一个工作表中显示所有 PDF 文件名及其页码。请按照以下步骤操作：

1. 打开要获取 Pdf 文件和页码的工作表。

2. 按住“ALT” + “F11”键，打开“Microsoft Visual Basic for Applications”窗口。

3. 点击“插入”>“模块”，然后将以下宏粘贴到“模块”窗口中。

VBA 代码：列出工作表中的所有 Pdf 文件名和页码：

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. 粘贴代码后，按“F5”键运行此代码，会弹出一个“浏览”窗口，请选择包含要列出并计算页数的 Pdf 文件的文件夹，参见截图：

5. 然后，点击“确定”按钮，所有 Pdf 文件名和页码都会列在当前工作表中，参见截图：