如何在Excel中保存或保留对ActiveX列表框的选择？

假设您已经创建了一些列表框并在列表框中进行了选择，但是，当关闭并重​​新打开工作簿时，这些列表框的所有选择都消失了。 您是否要在关闭并重新打开工作簿时保留在列表框中所做的选择？ 本文中的方法可以为您提供帮助。

使用Excel中的VBA代码保存或保留ActiveX列表框的选择

使用Excel中的VBA代码保存或保留ActiveX列表框的选择

如果Excel中有ActiveX列表框，则下面的VBA代码可以帮助您保存或保留选择。 请执行以下操作。

1.在工作簿中包含您要保留选择的ActiveX列表框，按 其他 + F11 同时打开 Microsoft Visual Basic应用程序 窗口。

2.在 Microsoft Visual Basic应用程序 窗口，双击 的ThisWorkbook 在左窗格中打开 的ThisWorkbook 代码 窗口。 然后将以下VBA代码复制到代码窗口中。

VBA代码：在Excel中保存对ActiveX列表框的选择

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim I As Long
    Dim J As Long
    Dim K As Long
    Dim KK As Long
    Dim xSheet As Worksheet
    Dim xListBox As Object
    On Error GoTo Label
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    K = 0
    KK = 0
    If Not Sheets("ListBox Data") Is Nothing Then
        Sheets("ListBox Data").Delete
    End If
Label:
    Sheets.Add(after:=Worksheets(Worksheets.Count)).Name = "ListBox Data"
    Set xSheet = Sheets("ListBox Data")
    For I = 1 To Sheets.Count
        For Each xListBox In Sheets(I).OLEObjects
            If xListBox.Name Like "ListBox*" Then
                With xListBox.Object
                For J = 0 To .ListCount - 1
                    If .Selected(J) Then
                        xSheet.Range("A1").Offset(K, KK).Value = "True"
                    Else
                        xSheet.Range("A1").Offset(K, KK).Value = "False"
                    End If
                    K = K + 1
                Next
                End With
                K = 0
                KK = KK + 1
            End If
        Next
    Next
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

Private Sub Workbook_Open()
    Dim I As Long
    Dim J As Long
    Dim KK As Long
    Dim xRg As Range
    Dim xCell As Range
    Dim xListBox As Object
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    KK = 0
    For I = 1 To Sheets.Count - 1
        For Each xListBox In Sheets(I).OLEObjects
            If xListBox.Name Like "ListBox*" Then
                With xListBox.Object
                    Set xRg = Intersect(Sheets("ListBox Data").Range("A1").Offset(0, KK).EntireColumn, Sheets("ListBox Data").UsedRange)
                    For J = 1 To .ListCount
                        Set xCell = xRg(J)
                        If xCell.Value = "True" Then
                            .Selected(J - 1) = True
                        End If
                    Next
                    KK = KK + 1
                End With
            End If
        Next
    Next
    Sheets("ListBox Data").Delete
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

3。 按 其他 + Q 关闭键 Microsoft Visual Basic应用程序 窗口。

4.现在，您需要将工作簿另存为启用了Excel Macro的工作簿。 请点击 文件 > 另存为 > 浏览.

5.在 另存为 对话框中，选择一个文件夹来保存工作簿，根据需要将其重命名，然后选择 Excel启用宏的工作簿 ，在 保存类型 下拉列表，最后单击 已保存 按钮。 看截图：

每次更新列表框时，请保存工作簿。 重新打开工作簿后，所有以前的选择都将保留在列表框中。

备注：保存工作簿时，名为“列表框数据”将在工作簿所有工作表的末尾自动创建，请忽略此工作表，因为它在工作簿关闭时会自动消失。