如何在Excel中仅允许选择一组复选框中的一个？

如下图所示，对于第2行列出的一组复选框，当选择或勾选一个复选框时，其他所有复选框都会自动禁用。如何实现这一功能？本文中的VBA代码可以帮助您完成。

使用VBA代码仅允许选择一个复选框

使用VBA代码仅允许选择一个复选框

您可以运行以下VBA代码，每次仅选择复选框组中的一个复选框。请按照以下步骤操作：

1. 首先，请根据需要插入复选框。这里，您应该插入ActiveX Control复选框，如下图所示：

2. 然后同时按Alt + F11键打开Microsoft Visual Basic for Applications窗口。

3. 在打开的Microsoft Visual Basic for Applications窗口中，点击“插入” > “类模块”。

4. 将类名称更改为ClsChk，在属性窗格的（名称）框中进行修改，然后复制并将以下VBA代码粘贴到相应的代码窗口中。见截图：

VBA代码1：每次仅选择一个复选框

Option Explicit
Public WithEvents Chk As MSForms.CheckBox
Private Sub Chk_Click()
Call SelOneCheckBox(Chk)
End Sub

Sub SelOneCheckBox(Target As Object)
Dim xObj As Object
Dim I As String
Dim n As Integer
If Target.Object.Value = True Then

    I = Right(Target.Name, Len(Target.Name) - 8)
    For n = 1 To ActiveSheet.OLEObjects.Count
      If n <> Int(I) Then
        Set xObj = ActiveSheet.OLEObjects.Item(n)
        xObj.Object.Value = False
        xObj.Object.Enabled = False
      End If
    Next
Else
    I = Right(Target.Name, Len(Target.Name) - 8)
    For n = 1 To ActiveSheet.OLEObjects.Count
      If n <> Int(I) Then
        Set xObj = ActiveSheet.OLEObjects.Item(n)
        xObj.Object.Enabled = True
      End If
    Next
End If
End Sub

5. 现在点击“插入” > “模块”，然后将以下VBA代码复制并粘贴到模块窗口中。

VBA代码2：每次仅选择一个复选框

Dim xCollection As New Collection
Public Sub ClsChk_Init()
Dim xSht As Worksheet
Dim xObj As Object
Dim xChk As ClsChk
   Set xSht = ActiveSheet
   Set xCollection = Nothing
    For Each xObj In xSht.OLEObjects
        If xObj.Name Like "CheckBox**" Then
            Set xChk = New ClsChk
            Set xChk.Chk = CallByName(xSht, xObj.Name, VbGet)
            xCollection.Add xChk
        End If
    Next
    Set xChk = Nothing
End Sub

6. 按F5键运行代码。

从现在开始，当在工作表中勾选任意一个复选框时，所有其他复选框都会自动禁用，并且您可以取消勾选以重新激活所有复选框。

注意：如果向复选框组添加了新的复选框，请重新运行VBA代码以再次激活所有复选框。从复选框组中删除复选框也需要重新运行代码。

相关文章：

• 如何在Excel中基于复选框筛选数据？
• 如何在Excel中隐藏行时隐藏复选框？
• 如何在Excel中通过复选框突出显示单元格或整行？
• 如何在Excel中创建带多个复选框的下拉列表？
• 如何在Excel中勾选复选框时向单元格插入时间戳？