如何在Excel中比较两个字符串的相似性或突出显示差异？

在某些情况下，您可能只需要比较两个相邻的字符串单元格，并在Excel中标记它们的相似性或差异。本文提供了两种方法帮助您实现这一目标。

使用公式比较两个字符串
使用VBA代码比较两个字符串的相似性或突出显示差异

使用公式比较两个字符串

如下截图所示，如果您只想知道被比较的字符串是否匹配，可以应用以下公式。

1. 选择一个空白单元格C2，在编辑栏中输入公式 =EXACT(A2, B2)，然后按Enter键。请参见截图：

备注：在公式中，A2和B2是包含要比较字符串的单元格。

2. 继续选择结果单元格，然后拖动填充柄到其他单元格，直到获得所有比较结果。

FALSE结果表示被比较的字符串不同，TRUE结果表示两个被比较的字符串匹配。请参见截图：

使用 Kutools AI 解锁 Excel 魔法

• 智能执行：执行单元格操作、分析数据和创建图表——所有这些都由简单命令驱动。
• 自定义公式：生成量身定制的公式，优化您的工作流程。
• VBA 编码：轻松编写和实现 VBA 代码。
• 公式解释：轻松理解复杂公式。
• 文本翻译：打破电子表格中的语言障碍。

通过人工智能驱动的工具增强您的 Excel 能力。立即下载，体验前所未有的高效！

使用VBA代码比较两个字符串的相似性或突出显示差异

如果您想比较两个字符串并突出显示它们之间的相似性或差异，以下VBA代码可以帮助您。

1. 同时按下Alt + F11键打开Microsoft Visual Basic for Applications窗口。

2. 在Microsoft Visual Basic for Applications窗口中，点击插入 > 模块。然后将以下代码复制并粘贴到代码窗口中。

VBA代码：比较两列字符串的相似性或突出显示差异

Sub highlight()
    Dim xRg1 As Range
    Dim xRg2 As Range
    Dim xTxt As String
    Dim xCell1 As Range
    Dim xCell2 As Range
    Dim I As Long
    Dim J As Integer
    Dim xLen As Integer
    Dim xDiffs As Boolean
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
lOne:
    Set xRg1 = Application.InputBox("Range A:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg1 Is Nothing Then Exit Sub
    If xRg1.Columns.Count > 1 Or xRg1.Areas.Count > 1 Then
        MsgBox "Multiple ranges or columns have been selected ", vbInformation, "Kutools for Excel"
        GoTo lOne
    End If
lTwo:
    Set xRg2 = Application.InputBox("Range B:", "Kutools for Excel", "", , , , , 8)
    If xRg2 Is Nothing Then Exit Sub
    If xRg2.Columns.Count > 1 Or xRg2.Areas.Count > 1 Then
        MsgBox "Multiple ranges or columns have been selected ", vbInformation, "Kutools for Excel"
        GoTo lTwo
    End If
    If xRg1.CountLarge <> xRg2.CountLarge Then
       MsgBox "Two selected ranges must have the same numbers of cells ", vbInformation, "Kutools for Excel"
       GoTo lTwo
    End If
    xDiffs = (MsgBox("Click Yes to highlight similarities, click No to highlight differences ", vbYesNo + vbQuestion, "Kutools for Excel") = vbNo)
    Application.ScreenUpdating = False
    xRg2.Font.ColorIndex = xlAutomatic
    For I = 1 To xRg1.Count
        Set xCell1 = xRg1.Cells(I)
        Set xCell2 = xRg2.Cells(I)
        If xCell1.Value2 = xCell2.Value2 Then
            If Not xDiffs Then xCell2.Font.Color = vbRed
        Else
            xLen = Len(xCell1.Value2)
            For J = 1 To xLen
                If Not xCell1.Characters(J, 1).Text = xCell2.Characters(J, 1).Text Then Exit For
            Next J
            If Not xDiffs Then
                If J <= Len(xCell2.Value2) And J > 1 Then
                    xCell2.Characters(1, J - 1).Font.Color = vbRed
                End If
            Else
                If J <= Len(xCell2.Value2) Then
                    xCell2.Characters(J, Len(xCell2.Value2) - J + 1).Font.Color = vbRed
                End If
            End If
        End If
    Next
    Application.ScreenUpdating = True
End Sub

3. 按F5键运行代码。在第一个Kutools for Excel对话框中，选择需要比较的第一列文本字符串，然后点击确定按钮。

4. 然后弹出第二个Kutools for Excel对话框，请选择第二列字符串，然后点击确定按钮。

5. 在最后一个Kutools for Excel对话框中，如果要比较字符串的相似性，请点击“是”按钮；要突出显示被比较字符串的差异，请点击“否”按钮。请参见截图：

然后您可以像下面的截图一样看到比较结果。

相关文章：

• 如何在Excel中比较两列并突出显示不匹配的数据？
• 如何在Excel中精确比较两个字符串（区分大小写）？