如何在 Excel 中生成或列出所有可能的排列？

例如，我有三个字符 XYZ，现在，我想根据这三个字符列出所有可能的排列，得到六个不同的结果，如：XYZ、XZY、YXZ、YZX、ZXY 和 ZYX。在 Excel 中，如何根据不同数量的字符快速生成或列出所有排列呢？

使用 VBA 代码基于字符生成或列出所有可能的排列

使用 VBA 代码基于字符生成或列出所有可能的排列

以下 VBA 代码可以帮助您根据特定数量的字母列出所有排列，请按照以下步骤操作：

1. 按住 ALT + F11 键打开 Microsoft Visual Basic for Applications 窗口。

2. 单击 插入 > 模块，并将以下代码粘贴到模块窗口中。

VBA 代码：列出 Excel 中所有可能的排列

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3. 然后按 F5 键运行此代码，会弹出一个提示框，提醒您输入要列出所有排列的字符，见截图：

4. 输入字符后，点击 确定 按钮，所有可能的排列将显示在活动工作表的 A 列中。见截图：

备注：如果输入的字符长度等于或大于 8 个字符，此代码将无法工作，因为排列的数量太多。