如何在 Excel 中将货币转换为英文大写？

对于将英语作为第二语言的非母语人士来说，当数字过长时，有时很难直接将货币数字转换为英文大写。本文将教您如何轻松地在 Excel 中将货币转换为英文大写。

使用 VBA 代码将货币转换为大写
使用 Kutools for Excel 将货币转换为大写

通过以下 VBA 代码，您可以将货币数字转换为英文大写。

1. 按 Alt + F11 打开 Microsoft Visual Basic for Applications 对话框。

2. 在 Microsoft Visual Basic for Applications 对话框中，点击 插入 > 模块。然后复制并将以下代码粘贴到代码窗口中。

VBA 代码：将货币数字转换为英文大写

Function NumberstoWords(ByVal pNumber)
Dim Dollars, Cents
arr = Array("", "", " Thousand ", " Million ", " Billion ", " Trillion ")
pNumber = Trim(Str(pNumber))
xDecimal = InStr(pNumber, ".")
If xDecimal > 0 Then
    Cents = GetTens(Left(Mid(pNumber, xDecimal + 1) & "00", 2))
    pNumber = Trim(Left(pNumber, xDecimal - 1))
End If
xIndex = 1
Do While pNumber <> ""
    xHundred = ""
    xValue = Right(pNumber, 3)
    If Val(xValue) <> 0 Then
        xValue = Right("000" & xValue, 3)
        If Mid(xValue, 1, 1) <> "0" Then
            xHundred = GetDigit(Mid(xValue, 1, 1)) & " Hundred "
        End If
        If Mid(xValue, 2, 1) <> "0" Then
            xHundred = xHundred & GetTens(Mid(xValue, 2))
        Else
            xHundred = xHundred & GetDigit(Mid(xValue, 3))
        End If
    End If
    If xHundred <> "" Then
        Dollars = xHundred & arr(xIndex) & Dollars
    End If
    If Len(pNumber) > 3 Then
        pNumber = Left(pNumber, Len(pNumber) - 3)
    Else
        pNumber = ""
    End If
    xIndex = xIndex + 1
Loop
Select Case Dollars
    Case ""
        Dollars = "No Dollars"
    Case "One"
        Dollars = "One Dollar"
    Case Else
        Dollars = Dollars & " Dollars"
End Select
Select Case Cents
    Case ""
        Cents = " and No Cents"
    Case "One"
        Cents = " and One Cent"
    Case Else
        Cents = " and " & Cents & " Cents"
End Select
NumberstoWords = Dollars & Cents
End Function
Function GetTens(pTens)
Dim Result As String
Result = ""
If Val(Left(pTens, 1)) = 1 Then
    Select Case Val(pTens)
        Case 10: Result = "Ten"
        Case 11: Result = "Eleven"
        Case 12: Result = "Twelve"
        Case 13: Result = "Thirteen"
        Case 14: Result = "Fourteen"
        Case 15: Result = "Fifteen"
        Case 16: Result = "Sixteen"
        Case 17: Result = "Seventeen"
        Case 18: Result = "Eighteen"
        Case 19: Result = "Nineteen"
        Case Else
    End Select
Else
Select Case Val(Left(pTens, 1))
    Case 2: Result = "Twenty "
    Case 3: Result = "Thirty "
    Case 4: Result = "Forty "
    Case 5: Result = "Fifty "
    Case 6: Result = "Sixty "
    Case 7: Result = "Seventy "
    Case 8: Result = "Eighty "
    Case 9: Result = "Ninety "
    Case Else
End Select
Result = Result & GetDigit(Right(pTens, 1))
End If
GetTens = Result
End Function
Function GetDigit(pDigit)
Select Case Val(pDigit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
    Case Else: GetDigit = ""
End Select
End Function

3. 同时按 Alt + Q 键关闭 Microsoft Visual Basic for Applications 对话框。

4. 选择一个空白单元格（B1），该单元格与您要转换为大写的单元格相邻，输入公式 =NumberstoWords(A1)，然后按 Enter 键。

备注：A1 是包含货币数字的单元格。您可以根据需要更改它。

5. 选中 B1 单元格，向下拖动填充柄以获取所有货币数字的英文大写形式。

这段冗长的 VBA 代码看起来很复杂。在这里，我将向您介绍一个方便的工具来轻松解决这个问题。借助 Kutools for Excel 的“小写金额转大写”工具，将货币转换为大写将不再是问题。请按照以下步骤操作。

1. 选择包含要转换的货币数字的单元格。

2. 点击 Kutools > 文本 > 小写金额转大写。参见截图：

3. 在“小写金额转大写”对话框中，选择 英语 转换选项，并点击 确定 或 应用 按钮。

现在，所选的货币数字立即被转换为英文大写。