如何在 Excel 中使用一个或多个条件进行求和？

在 Excel 中，基于一个或多个条件对数值进行求和是我们大多数人的常见任务。SUMIF 函数可以帮助我们根据一个条件快速求和，而 SUMIFS 函数则帮助我们根据多个条件求和。本文将详细介绍如何在 Excel 中使用一个或多个条件进行求和。

在 Excel 中按单个条件求和单元格值

在 Excel 中按多个条件求和单元格值

在 Excel 中按单个条件求和单元格值

首先，我将为您提供 SUMIF 语法以供参考：

SUMIF(区域, 条件, [求和区域])

• 区域：要根据条件评估的单元格范围；
• 条件：您希望使用的条件；
• 求和区域：如果条件满足，则要求和的单元格范围

为了应用此 SUMIF 函数，我将以以下数据为例：

(1.) 当产品为“KTE”时的数量总和：

=SUMIF(A2:A12,E2,C2:C12) 然后按 Enter 键获取结果，(A2:A12 是包含条件的单元格范围，E2 是您希望基于其求和的条件，C2:C12 指的是您希望求和的范围)，请参见截图：

(2.) 对所有非“KTE”产品的数量求和：

=SUMIF(A2:A12,"<>KTE",C2:C12)，然后按 Enter 键计算除 KTE 以外的所有产品数量总和，(A2:A12 是包含条件的单元格范围，<>KTE 是排除 KTE 的条件，C2:C12 指的是您希望求和的范围)，请参见截图：

(3.) 对大于 250 的数量求和：

=SUMIF(C2:C12,">250")，然后按 Enter 键获取结果，(C2:C12 指的是您希望求和的范围，>250 是您需要的条件，您也可以根据需要将其更改为小于 250)，请参见截图：

(4.) 使用带有多个 OR 条件的 SUMIF+SUMIF+… 函数，对 KTE 和 KTW 的数量求和：

=SUMIF(A2:A12,"KTE",C2:C12) + SUMIF(A2:A12,"KTW",C2:C12)( A2:A12 是包含条件的单元格范围，KTE 和 KTW 是您希望基于其求和的条件，C2:C12 指的是您希望求和的范围)，然后按 Enter 键获取结果：

在 Excel 中按多个条件求和单元格值

SUMIFS 语法如下：

SUMIFS(求和区域, 条件区域1, 条件1,[条件区域2, 条件2],...)

• 求和区域：要求和的单元格范围；
• 条件区域1：具有第一个条件的范围；
• 条件1：必须满足的第一个条件；
• 条件区域2, 条件2, ...：这些是与之关联的附加范围和条件。

(1.) 对产品为 KTE 且名称为 James 的数量求和：

请输入此公式：=SUMIFS(C2:C12,A2:A12,"KTE",B2:B12,"James"),(C2:C12 是需要求和的单元格范围，A2:A12, KTE 是第一个条件范围和条件，B2:B12, James, 是第二个条件范围和条件)，然后按 Enter 键，请参见截图：

这里还有一个数组公式可以帮助您：=SUM((A2:A12="kte")*(B2:B12="James")*C2:C12)，输入公式后需要同时按下 Ctrl + Shift + Enter 键。

(2.) 对产品为 KTE 且名称不是 James 的数量求和

输入此公式：=SUMIFS(C2:C12,A2:A12,"KTE",B2:B12,"<>James")(C2:C12 是需要求和的单元格范围，A2:A12, KTE 是第一个条件范围和条件，B2:B12, <>James, 是第二个条件范围和条件)，然后按 Enter 键获取结果，请参见截图：

另一个数组公式也可以完成此操作：=SUM((A2:A12="kte")*(B2:B12<>"James")*C2:C12)，但输入此公式后必须按 Ctrl + Shift + Enter 键。

(3.) 对产品为 KTE 且数量大于 150 的数量求和

您可以使用此 SUMIFS 公式：=SUMIFS(C2:C12,A2:A12,"KTE",C2:C12,">150")(C2:C12 是需要求和的单元格范围，A2:A12, KTE 是第一个条件范围和条件，C2:C12, >150, 是第二个条件范围和条件)，然后按 Enter 键返回结果。

您还可以使用 SUM 数组公式来获取所需的结果，=SUM((A2:A12="kte")*(C2:C12>150)*C2:C12) 请记住，在输入此公式后按 Ctrl + Shift + Enter 键。

(4.) 对数量介于 100 到 200 之间的数量求和

要对两个数字之间的值求和，请使用此公式：=SUMIFS(C2:C12,C2:C12,">100",C2:C12,"<200")( C2:C12 是需要求和的单元格范围，C2:C12 , >100 是第一个条件范围和条件，C2:C12, <200, 是第二个条件范围和条件)，然后按 Enter 键获取如下结果：

当然，SUM 数组公式也可以帮助您，=SUM((C2:C12>100)*(C2:C12<200)*C2:C12)，请记住同时按 Ctrl + Shift + Enter 键以获得正确结果。

相关文章：

如何在 Excel 中基于单一条件对多列求和？

如何在 Excel 中对包含文本和数字的单元格求和？