如何列出工作簿中的所有数据透视表？

假设您有一个包含多个数据透视表的大型工作簿，现在，您要列出此工作簿中的所有数据透视表，是否可以？ 当然，本文中的以下VBA代码将帮您一个忙。 要了解更多详细信息，请阅读以下文章。

使用VBA代码列出工作簿中的所有数据透视表

使用VBA代码列出工作簿中的所有数据透视表

以下VBA代码可以帮助您列出所有数据透视表名称及其属性，例如源数据范围，工作表名称，刷新日期等。

1. 打开您要列出所有数据透视表的工作簿。

2。 按住 ALT + F11 键，然后打开 Microsoft Visual Basic for Applications窗口.

3。 点击 插页 > 模块，然后将以下代码粘贴到 模块窗口.

VBA代码：列出工作簿中的所有数据透视表

Sub ListPivotsInfor()
'Update 20141112
    Dim St As Worksheet
    Dim NewSt As Worksheet
    Dim pt As PivotTable
    Dim I, K As Long
    Application.ScreenUpdating = False
    Set NewSt = Worksheets.Add
    I = 1: K = 2
    With NewSt
        .Cells(I, 1) = "Name"
        .Cells(I, 2) = "Source"
        .Cells(I, 3) = "Refreshed by"
        .Cells(I, 4) = "Refreshed"
        .Cells(I, 5) = "Sheet"
        .Cells(I, 6) = "Location"
        For Each St In ActiveWorkbook.Worksheets
            For Each pt In St.PivotTables
                I = I + 1
                .Cells(I, 1).Value = pt.Name
                .Cells(I, 2).Value = pt.SourceData
                .Cells(I, 3).Value = pt.RefreshName
                .Cells(I, 4).Value = pt.RefreshDate
                .Cells(I, 5).Value = St.Name
                .Cells(I, 6).Value = pt.TableRange1.Address
            Next
        Next
        .Activate
    End With
    Application.ScreenUpdating = True
End Sub

4。 然后按 F5 运行此代码的关键，所有数据透视表名称，源数据范围，工作表名称和其他属性都列在新工作表中，该新工作表位于活动工作表的前面，如以下屏幕快照所示：

相关文章：

如何检查工作簿中是否存在数据透视表？

如何将多个字段添加到数据透视表？