如何在Outlook中为答复和转发设置不同的签名？

通常，您可以在Outlook中为不同的帐户设置不同的签名，但是，曾经尝试对答复和转发应用不同的签名。这意味着，当您回复电子邮件时，将插入signature1；当您转发电子邮件时，将应用signature2。您如何在Outlook中解决此任务？

设置不同的签名以使用VBA代码进行答复和转发

设置不同的签名以使用VBA代码进行答复和转发

以下VBA代码可以帮助您为回复和转发设置不同的签名，请按以下步骤进行操作：

1。按住 ALT + F11 键打开 Microsoft Visual Basic应用程序 窗口。

2。然后，点击插页 > 模块，将以下代码复制并粘贴到打开的空白模块中，请参见屏幕截图：

VBA代码：为回复和转发设置不同的签名:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

备注：在上面的代码中， Signature1 和 Signature2 是您要用于回复和转发的两个签名名称。请根据需要更改名称。

doc sig forwar回复1